POV-Ray : Newsgroups : povray.binaries.images : Cool mathematical object Server Time
29 Mar 2024 04:03:20 EDT (-0400)
  Cool mathematical object (Message 1 to 10 of 10)  
From: scam
Subject: Cool mathematical object
Date: 30 May 2006 09:30:01
Message: <web.447c45efc019fdb45c947f990@news.povray.org>
Hi all,

I originally made this image over a year ago, however at that time the
version of POV-Ray I was using had a bug which made the sphere_sweep
objects very glitchy. It remained that way until Florian pointed out that
the bug wasn't present in a previous version (3.5) and so all of a sudden I
was back in business.

Anyway here is the image. It is an inversion of a 3D truchet tiling, where
instead of the mesh it was originally made with I now have nice smooth
sphere sweeps (which look much better, and are ~ an order of magnitude
faster to render). Render time was about 2 hours.

While I have your attention, does any one have any alternate
texture/lighting ideas? At the moment I just have an area light and a red
point source inside the object, and a very basic texture.


Post a reply to this message


Attachments:
Download 'sphere sweep.png' (288 KB)

Preview of image 'sphere sweep.png'
sphere sweep.png


 

From: Ben Chambers
Subject: Re: Cool mathematical object
Date: 30 May 2006 11:30:56
Message: <447c6530$1@news.povray.org>
scam wrote:
> While I have your attention, does any one have any alternate
> texture/lighting ideas? At the moment I just have an area light and a red
> point source inside the object, and a very basic texture.

Try this for the object:
texture {
	pigment {color transmit 1}
	finish {specular 0.75 reflection {0, 0.5}}
}
interior {
	ior 2.5
}


Then, if you feel like your computer is rendering too fast, you could 
also add dispersion (but I'm not as experienced w/ that) :)

...Chambers


Post a reply to this message

From: Sven Littkowski
Subject: Re: Cool mathematical object
Date: 30 May 2006 11:51:14
Message: <447c69f2$1@news.povray.org>
Great artwork!

Great harmony between colors and shapes. Hmm, maybe missing is a foggy 
sphere (media scattering, ambient) of red color in the center, just an idea.

I like it!

Greetings,

Sven


Post a reply to this message

From: Ross
Subject: Re: Cool mathematical object
Date: 30 May 2006 12:38:39
Message: <447c750f$1@news.povray.org>
"Ben Chambers" <ben### [at] pacificwebguycom> wrote in message
news:447c6530$1@news.povray.org...
> scam wrote:
> > While I have your attention, does any one have any alternate
> > texture/lighting ideas? At the moment I just have an area light and a
red
> > point source inside the object, and a very basic texture.
>
> Try this for the object:
> texture {
> pigment {color transmit 1}
> finish {specular 0.75 reflection {0, 0.5}}
> }
> interior {
> ior 2.5
> }
>
>
> Then, if you feel like your computer is rendering too fast, you could
> also add dispersion (but I'm not as experienced w/ that) :)
>
> ...Chambers

Or add some SSS media :)


Post a reply to this message

From: Florian Brucker
Subject: Re: Cool mathematical object
Date: 30 May 2006 12:53:15
Message: <447c787b$1@news.povray.org>
Ah, sphere inversions, I love those! Glad my tip enabled you to render 
it properly!

Textures could be more interesting, that's true, but first I'd go for a 
different perspective - this one is a little boring. Looking along one 
of the longer "tails" into the knot could improve that a lot.


HTH,
Florian


Post a reply to this message

From: Sven Littkowski
Subject: Re: Cool mathematical object
Date: 30 May 2006 15:12:39
Message: <447c9927$1@news.povray.org>
"scam" <sca### [at] mailusydeduau> schrieb im Newsbeitrag 
news:web.447c45efc019fdb45c947f990@news.povray.org...
> While I have your attention, does any one have any alternate
> texture/lighting ideas?


Hi Scam,

Hmm, different textures? I truly like the current one. But here are my 
ideas:

1
Chrome
2
Tiger fur with white (belly area of a real tiger), brown-yellow and black 
parts
3
Gold
4
Green glass with a bumby surface

Greetings,

Sven


Post a reply to this message

From: scam
Subject: Re: Cool mathematical object
Date: 31 May 2006 02:45:01
Message: <web.447d3ae752ae62aa58a931fb0@news.povray.org>
Thanks guys, some good suggestions there. I'm cooking up something at the
moment that involves a new perspective and media, so stay tuned!


Post a reply to this message

From: Paul Bourke
Subject: Re: Cool mathematical object
Date: 31 May 2006 03:46:40
Message: <pdbNOSPAM-A7776F.17464031052006@news.povray.org>
> Anyway here is the image. It is an inversion of a 3D truchet tiling

Looks great!
Can you share the source so others can explore it?

-- 
Paul Bourke
pdb(NOSPAM)swin.edu.au


Post a reply to this message

From: Bill Pragnell
Subject: Re: Cool mathematical object
Date: 31 May 2006 05:35:01
Message: <web.447d625852ae62aa731f01d10@news.povray.org>
It's a superb object, and I rather like the plain texture and soft lighting
you've given it. It gets quite convoluted towards its centre, so any more
texturing might make it look too busy.

I too would be grateful for a peek at the source!

Bill


Post a reply to this message

From: scam
Subject: Re: Cool mathematical object
Date: 31 May 2006 07:45:00
Message: <web.447d804452ae62aa5c947f990@news.povray.org>
"Bill Pragnell" <bil### [at] hotmailcom> wrote:
>
> I too would be grateful for a peek at the source!
>
> Bill

Ask and you shall receive. I upload it on one condition though: I want to
see what you do with it!

The main parameter is the size of the tiling. A setting of 4 is fine for
renders from a distance.

----------------------------------------------

#include "rand.inc"
#include "colors.inc"
#include "rad_def.inc"
#include "functions.inc"


#declare num_phi1=8;
// number of points along 90 degrees of the
// major torus axis
#declare ninetydeginrads=3.14159265358/2;

#declare mytexture=     texture {
   pigment { color rgb <1, 1, 1> }
   finish {
     ambient color rgb <0, 0, 0>
     diffuse 1
   }
 }



// The functions defining the transformation of the 3D Trouchet tiling

#declare point_trans_x=function(x,y,z) {
 x/max(1e-8,x*x+y*y+z*z)
}
#declare point_trans_y=function(x,y,z) {
 y/max(1e-8,x*x+y*y+z*z)
}
#declare point_trans_z=function(x,y,z) {
 z/max(1e-8,x*x+y*y+z*z)
}

// This generates points of one quarter torus
// trans, rot is used for positioning the torus whithin the origin tile
// trans2, rot2 is used for translating/rotating the final tile

#macro _quarter_torus_tris(trans,rot,trans2,rot2)
  #declare _phi1 = -ninetydeginrads/num_phi1;
  #while (_phi1<=ninetydeginrads+ninetydeginrads/num_phi1)
    #declare p1 =
vrotate(vrotate(<sin(_phi1),-cos(_phi1)+1,0>,rot)+trans,rot2)+trans2;
    #declare p1 =
<point_trans_x(p1.x,p1.y,p1.z),point_trans_y(p1.x,p1.y,p1.z),point_trans_z(p1.x,p1.y,p1.z)>;
    p1,0.2*max(1e-8,pow(p1.x,2)+pow(p1.y,2)+pow(p1.z,2))
    #declare _phi1 = _phi1 + ninetydeginrads/num_phi1;
  #end
#end


// This generates the sphere sweeps for one complete
// tile with 3 quarter tori
#macro Trouchet_Tile(trans,rot)
union {
 sphere_sweep {
  cubic_spline
  num_phi1+3,
     _quarter_torus_tris(<-1,0,0>,0,trans,rot)
  tolerance 0.01
  texture{ mytexture}
 }

 sphere_sweep {
  cubic_spline
  num_phi1+3,
     _quarter_torus_tris(<1,0,-0>,<90,180,0>,trans,rot)
  tolerance 0.01
  texture{ mytexture}
 }
 sphere_sweep {
  cubic_spline
  num_phi1+3,
    _quarter_torus_tris(<0,0,1>,<0,90,180>,trans,rot)
  tolerance 0.01
  texture{ mytexture}
}
 scale 30

}
#end


// The seed for the 3D tiling
#declare rotseed=seed(2345143);
// This is the size of the tiling in cubes along
// each axis. Should be a multiple of 2.
#declare _size=4;

union{

#declare _x=-_size/2;
#while (_x<=_size/2)
 #declare _y=-_size/2;
 #while (_y<=_size/2)
   #declare _z=-_size/2;
   #while (_z<=_size/2)
     #declare rx=int(RRand(0,3,rotseed))-1;
     #declare ry=int(RRand(0,3,rotseed))-1;
     #declare rz=int(RRand(0,3,rotseed))-1;
// Here I remove the central tile before the
// inversion operation for aesthetic reasons
     #if (_x=0)
       #if (_y=0)
         #if(_z=0)
         #else
           Trouchet_Tile( <_x,_y,_z>*2 , <rx,ry,rz>*90 )
         #end
       #else
         Trouchet_Tile( <_x,_y,_z>*2 , <rx,ry,rz>*90 )
       #end
     #else
       Trouchet_Tile( <_x,_y,_z>*2 , <rx,ry,rz>*90 )
     #end
     #declare _z=_z+1;
   #end
   #declare _y=_y+1;
 #end
 #declare _x=_x+1;
#end

}


camera {
 location vnormalize(< 6, 2, -14>)*90
 look_at <0, 0, 0>
}

sky_sphere {
 pigment {
   gradient y
   color_map {
     [ 0.0 color rgb <1.1, 1.1, 2.> ]
     [ 0.5 color rgb <0,0,0> ]
     [ 1.0 color rgb <1.1, 1.1, 2.> ]
   }
   scale <1, 2, 1>
   translate y
 }
}


// Basic lighting

light_source { <6, 2, -14>*90 color White }

// Or for radiosity comment out the above
// light source, and use the following:

/* light_source {
  <3, -5, -2>*20
  color rgb <0.95, 0.78, 0.42>
  area_light
  10*x, 10*z,
  4, 4
  jitter
  orient
}

light_source {
    <0, 0, 0>
    color Red
    shadowless
    fade_distance 10
    fade_power 2

  }

global_settings { radiosity { Rad_Settings(Radiosity_Normal, off, off) } }

*/


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.