This is my first post on this newsgroup, so here is the reflective plane
over checkered sphere ;), with the source code:

camera {
 location <0,-2.5,-15>
 look_at -2.5*y
 sky <1,-5,0>
}

light_source {
 <500,500,-1000>
 color rgb 1
}

plane {
 y, -3
 pigment {
  color rgb <0.9,0.8,0.2>
 }
 finish {
  reflection { 1 metallic 1 }
  ambient 0
  diffuse 0.0
 }
}

sphere {
 0, 3
 pigment {
  cells
  color_map {
   [ 0 color rgbf <0.8,0.5,0.8,1> ]
   [ 1 color rgbf 1 ]
  }
 }
 interior {
  media {
   emission rgb 0.5
   intervals 100
   density {
    cells
    density_map {
     [ 0 color rgb -1 ]
     [ 1 color rgb <0.5,0.6,0.8> ]
    }
   }
  }
 }
 finish {
  specular 0.5/20
  roughness 0.3/20
 }
 rotate 51*z
 hollow
}

sky_sphere {
 pigment {
  gradient y
  color_map {
   [ 0 color rgb 1 ]
   [ 1 color rgb <0.5,0.6,0.9> ]
  }
 }
}

Post a reply to this message

Attachments:
Download 'reflsphere.jpg' (42 KB)

Preview of image 'reflsphere.jpg'

"asfiXy" <lef### [at] voilafr> wrote:
> This is my first post on this newsgroup, so here is the reflective plane
> over checkered sphere ;), with the source code:

That's funny (literally). I had the same idea recently, but hadn't thought
to use media patterns to make the cubes, being more of a constructionist. I
think a little distance between the sphere and the plane might give it a
more "classic" look. Thanks for the chuckle.

//Dave Dunn - hos### [at] aolcom
#local D = union { torus {1,.1 clipped_by {plane {-x,0}}} sphere
{<0,0,1>,.1} sphere {<0,0,-1>,.1} cylinder {<0,0,-1>,<0,0,1>,.1} pigment
{rgb .8} finish {ambient .5 reflection {.5}} rotate x*-90 translate
<-.5,.5,5>} object {D} object {D translate <.5,-1,0>} plane {y,-2 pigment
{checker rgb 1, rgb 0 scale 5} finish {ambient .5}}

Post a reply to this message

OK, that *is* cool. :-)

Post a reply to this message

asfiXy nous apporta ses lumieres en ce 2005-05-05 16:36:
> This is my first post on this newsgroup, so here is the reflective plane
> over checkered sphere ;), with the source code:
>
>  interior {
>   media {
>    emission rgb 0.5
>    intervals 100
>    density {
>     cells
>     density_map {
>      [ 0 color rgb -1 ]
>      [ 1 color rgb <0.5,0.6,0.8> ]
>     }
>    }
>   }
>  }
>
Very nice :)
One little thing, it renders WAY faster if you use "samples 100" instead of "intervals
100" for the 
media.
In my test, samples 100 renders in 18.52 seconds
intervals 100 takes 163.95 seconds! About 8.8 times longer for the same result.

Alain

Post a reply to this message

you're right.
Thank you

Post a reply to this message