This is my first attempt with making something nice with isosurfaces (and
first image post here). I think it looks pretty good. :D
I'm planning on making a water type faucet and sticking it in the side with
some liquid dripping out. Weee!
--------------------------
#include "colors.inc"
#include "textures.inc"

#declare debugin = false;

global_settings{
  max_trace_level 5
  #if (debugin = false)
  radiosity {
      pretrace_start 0.08
      pretrace_end   0.04
      count 20
      nearest_count 5
      error_bound 0.2
      recursion_limit 1
      low_error_factor 0.5
      gray_threshold 0.0
      minimum_reuse 0.015
      brightness 1
      adc_bailout 0.02
  }
  #end
}

background{White}

camera {
  location<1, 1.6,-2.5> look_at<0,0,0> //topish view
}

light_source {
  <-200,320,15>, rgb 0.7 //adaptive 1
}

union{
  difference{
    isosurface { //whole trunk and bark
      function{-f_cylindrical(x,y,z)-f_agate(x*5,y*1.43,z*5)/8 + 0.2}
      threshold 0
      contained_by{box {<-1,-1,-1>,<1,1,1>}}
      max_gradient 3
      pigment {  //color bark depending on radius
        wood
        color_map{
          //dark ring color divided by 2.3
          [0.0 color rgb 2*<0.5019, 0.25, 0>/2.3]
          //dark ring color divided by 3.5
          [1.0 color rgb 2*<0.5019, 0.2, 0>/3.5]

          //test colors to show gradient
          //[0.0 color rgb<1, 0, 0>] //red
          //[1.0 color rgb<0, 0, 1>] //blue
        }
        scale 0.08
        rotate x*90
        rotate y*30
        turbulence 0.06
        phase pi/2  //adjust so highest are dark
      }
      finish{reflection 0.001 diffuse 0.4 crand .3 ambient 0}
    }
    isosurface { //cut out trunk
      function{-f_cylindrical(x,y,z)-f_agate(x/.2,y/.7,z/.2)/14+.26}
      threshold 0
      contained_by{box {<-1,-1.1,-1>,<1,1.1,1>}}
      max_gradient 2
      pigment{Tan} //give cut mark tan color in hopes of sap appearence
    }
  }

  isosurface {  //add trunk back in with different texture
    function{-f_cylindrical(x,y,z)-f_agate(x/.2,y/.7,z/.2)/14+.26}
    threshold 0
    contained_by{box {<-1,-1,-1>,<1,1.1,1>}}
    max_gradient 2
    pigment {
      wood
      color_map{
        [0.0 color rgb 2*<0.5019, 0.25, 0>]
        [0.4 color rgb 2*<0.5019, 0.25, 0>]
        [1.0 color rgb 2*<0.5019, 0.2, 0>/2]
      }
      scale 0.08
      rotate x*90
      rotate y*30
      turbulence 0.04
    }
    finish{diffuse 0.4 crand .2 ambient .1}
    normal{
      average
      normal_map{
        [0.2 wrinkles 1 scale 1 scale y*2]
        [1.4 granite 1 scale 0.08 scale y*0.45]
      }
    }
  }
}
--------------------------

Post a reply to this message

Attachments:
Download 'log_single.jpg' (60 KB)

Preview of image 'log_single.jpg'

A bit dark but really very nice!
;-)
Paolo
> This is my first attempt with making something nice with isosurfaces (and
> first image post here). I think it looks pretty good. :D
> I'm planning on making a water type faucet and sticking it in the side
with
> some liquid dripping out. Weee!

Post a reply to this message

The shape of the trunk is very nice. The texture isn't great, though, and
kind of ruins the effect. The color is too orange, and there are not enough
rings: only 11 indicates that this tree was eleven years old when it died.
This doesn't match with the very rough/rugged looking bark on the trunk.
:-)

 - dan B hentschel

Post a reply to this message

"dan B hentschel" <dan### [at] alumritedu> wrote:
> The shape of the trunk is very nice. The texture isn't great, though, and
> kind of ruins the effect. The color is too orange, and there are not enough
> rings: only 11 indicates that this tree was eleven years old when it died.
> This doesn't match with the very rough/rugged looking bark on the trunk.
> :-)
>
>  - dan B hentschel

Thanks dan, you told it like it was. I appriciate that. :)
You're right about the rings. I was going for redwood bark, so, I should
probably add a couple thousand more :P
Recalibrating my lcd made the brightness and color problems obviouse. Looks
much better now.

Thanks,
brandon

Post a reply to this message