How do I get corrugated roofing to work in this image? I can get the texture
effect to work using normals but the roof does not corrugate

Post a reply to this message

Attachments:
Download 'platform.jpg' (24 KB)

Preview of image 'platform.jpg'

I'm not sure that this is exactly what you are after, but can you use a 
height field and an internal bitmap?

Here is an example:

camera {
   location <0, 0, -200>
   look_at <0, 0, 0>
   rotate <45, -45, 0>
   }

light_source {
   <-2000, 4000, -3000>
   color rgb 2
   }

height_field {
   function 400, 400 {
     pattern {
       marble
       turbulence .075
       scale .25
       }
     }
   translate <-.5, 0, -.5>
   scale <100, 10, 100>
   texture {
     pigment {
       color rgb .5
       }
     finish {
       specular .5
       roughness .005
       reflection { 1, 1 }
       }
     }
   }

sphere {
   <0, 40, 0>
   20
   texture {
     pigment {
       color rgb <.75, 0, 0>
       }
     finish {
       specular 1
       roughness .005
       reflection .25
       }
     }
   }

Not exactly perfect, but it is something to work from.

Post a reply to this message

If only a normal is used you can only see it as light/shadow changes on an 
otherwise flat surface. Faster to render. Example:
normal {function {abs(x)} sine_wave scale 0.1}

Best way would be to use a sine wave function in an isosurface to get the 
actual shape. Here is a 3' by 16' panel.

#declare Freq=20;

isosurface {
    function {
         y-sin(x*Freq)/25
    }
    contained_by {
     box {<-1.5,-1,-8>,<1.5,1,8>} // could change x and z (W and L)
    }
    max_gradient 2 // adjust
    open // make surface only
    pigment {rgb 1}
    scale 1
}

I see Aaron Gillies has replied, too, about using HF. Which is certainly 
another possibilty, although not as easy and convenient.

Mike Williams has a isosurface tutorial (much suggested reading) showing a 
way to create a thickness, too, if that might matter. See last example at:
http://www.econym.demon.co.uk/isotut/substitute.htm

Bob H.

Post a reply to this message

> #declare Freq=20;
>
> isosurface {
>     function {
>          y-sin(x*Freq)/25
>     }
>     contained_by {
>      box {<-1.5,-1,-8>,<1.5,1,8>} // could change x and z (W and L)
>     }
>     max_gradient 2 // adjust
>     open // make surface only
>     pigment {rgb 1}
>     scale 1
> }

Cheers, I'll be sure to give you cred in my IRTC entry, but if I forget,
here it is.

Post a reply to this message

Attachments:
Download 'platform.jpg' (44 KB)

Preview of image 'platform.jpg'

"Bathurstfreak" <bat### [at] hotmailcom> wrote in message 
news:web.41d2a62a9b0fd5ad127a3fdf0@news.povray.org...
> Cheers, I'll be sure to give you cred in my IRTC entry

No need to do that. Was just a simple bit of help.

Your roof here looks much like the carport roof I built with the same kind 
of corrugated metal that I included in a model of my home made in POV-Ray, 
which is how I knew about the way to make it. Is 20' L by 16' W with five 4" 
X 4" posts on one side and other, higher side, attached to the home.

About your rendered image... Will you be using light source fading? Right 
now I can't tell much about the lighting, it has a high ambient appearance, 
or perhaps a shadowless light source.

Post a reply to this message