has anybody got any decent isosurface brick models ie a box with roughness
from 3d noise/ pigment patterns. I have been trying to model on but as I'm
not very good with isosurfaces am having difficulties
Thanks.

Post a reply to this message

Hi!

Try this one by Christoph Hormann (bottom of the page):
http://www-public.tu-bs.de:8080/~y0013390/pov/wtunnel.html

BTW, p.b.images is for posting images. Normal questions like yours 
should go to either povray.general, povray.newusers or 
povray.advanced-users.

HTH,
Florian

Post a reply to this message

"Vladimir" <nomail@nomail> wrote:
> has anybody got any decent isosurface brick models ie a box with roughness
> from 3d noise/ pigment patterns. I have been trying to model on but as I'm
> not very good with isosurfaces am having difficulties
> Thanks.

The brick wall in the Innocent Shadow image is decent
as long as you don't need a closeup (code available at
the IRTC website).

The wall has bricks vertically lined up with each other
(often found in very old brick walls) but you could fix
that with a small change.

-Mark Slone

Post a reply to this message

Vladimir wrote:

> has anybody got any decent isosurface brick models ie a box with roughness
> from 3d noise/ pigment patterns. I have been trying to model on but as I'm
> not very good with isosurfaces am having difficulties
> Thanks.

Hi Vladimir,

Here is a very simple (and not too good looking) example I recently used:

#declare fnbumps = function{pigment{granite}}                           
#declare fntile = function{x}

#declare abrick = object
{
 isosurface
 {
        function{fntile(x,y,z) + fnbumps(x,y,z).x * 0.112}
        max_gradient 0.719
        threshold 1
        
        contained_by
                {
                        box {-2,2}
                }                 
         rotate y*-90
 }        
 scale <0.35,0.35,0.01955>
}
                                  
#declare wallbrick = object
{
    
        abrick
        material
        {
               texture
               {
                     T_Stone2
                     finish
                     {
                        diffuse 0.75  
                        ambient 0.75
                     }
               }
         }            
         scale <0.75,0.35,4>
         rotate x*90        
}  

#declare wall = union
{
#declare xloc = -0.23;
#declare yloc = yloc + (1 * yfac) - 0.75;

#declare xfac = 1.075;
#declare zfac = 0.515;

#declare xcount = 9;

#while (xcount > 0)

#declare zloc = -0.7;
#declare zcount = 9;

#while (zcount > 0)
 object
 {
  wallbrick
  translate <xloc,yloc,zloc>
 }                            
 #declare zloc = zloc + zfac;
 #declare zcount = zcount - 1;
 #end             
 #declare xloc = xloc - xfac;
 #declare xcount = xcount - 1;
#end   
}

difference
{
 object
 {
  wall
 } 
  
union
{  
 box { 
  <-1, -1, -1>, <1, 1, 1>
  material {
    texture
    {
     T_Stone2
    }
  }
  scale <1.203208, 0.270298, 1.833007>
  translate  <-2.401552, 9.975676, 0.716774>
 } 
  
 box { 
   <-1, -1, -1>, <1, 1, 1>
   material {
     texture
     {   
      T_Stone2
     } 
   }
   scale <1.794289, 0.270298, 1.256064>
   translate  <-6.768104, 9.975676, 1.286108>
   }//Box    
 }//Union
}//Difference 

-- 
Stefan Viljoen
Software Support Technician
Polar Design Solutions

Post a reply to this message

Vladimir,

Pls have a look at my post on June 20th in this group. If this is what you
are looking
for, I may give you more info.

Rgds,

Groucho

"Vladimir" <nomail@nomail> wrote in message
news:web.411e293046c8aea5472e332c0@news.povray.org...
> has anybody got any decent isosurface brick models ie a box with roughness
> from 3d noise/ pigment patterns. I have been trying to model on but as I'm
> not very good with isosurfaces am having difficulties
> Thanks.
>

Post a reply to this message

I am posting this before looking at the links so If I say something stupid
please forgive me. I will look at them after posting this but My family is
telling me to get of the internet so they can use the phone. Firstly thanks
for the replies. from what Ive seen my questions have been answered. I
realise I have posted on the wrong board. I misread the title when I was
posting. I will post another reply When I have had chance to read the
links.

Thanks

Peter

Post a reply to this message

I have finally checked out the links.
The Brick posted by stefan is very good but when I experimented I found it
only textured on one side. I think this is because the bricks were based
around the function x and I will do some more experimenting trying out
functions to produce boxes.

Groucho- your pictures are great. I would be very interested in seing the
source code for the bricks.

The bricks I will be using in my final image will be whitewashed and
therefore I am trying to create a brick that looks good with minimal
texturing.

Thanks
Peter

Post a reply to this message

Here it goes:

#declare rr = seed(1234);

#macro T_Wall()
 pigment {rgb (0.8+0.15*rand(rr))*<0.3+0.02*rand(rr),0.3,0.3>}
 normal {
  granite
  scale 0.01
 }
 finish {diffuse 1.8}
#end

#macro BlockWall(l,h,w)
 #declare r=0.02;
 isosurface {
  function {
   f_rounded_box(x,y,z,r,l/2,h/2,w/2)+0.01*f_noise3d(10*x,10*y,10*z)
  }
  contained_by {box {<-l/2,-h/2,-w/2> <l/2,h/2,w/2>}}
  translate <l/2,h/2,w/2>
  texture {T_Wall()}
 }
#end

.Groucho.

"Vladimir" <nomail@nomail> wrote in message
news:web.412235209f026eba14f564e0@news.povray.org...
> I have finally checked out the links.
> The Brick posted by stefan is very good but when I experimented I found it
> only textured on one side. I think this is because the bricks were based
> around the function x and I will do some more experimenting trying out
> functions to produce boxes.
>
> Groucho- your pictures are great. I would be very interested in seing the
> source code for the bricks.
>
> The bricks I will be using in my final image will be whitewashed and
> therefore I am trying to create a brick that looks good with minimal
> texturing.
>
> Thanks
> Peter
>

Post a reply to this message

Thanks ,
Peter

Post a reply to this message