The leftmost sphere in each image has no dispersion.  The remaining  
spheres have dispersion_samples set to the number above each.  The first  
image uses faked caustics and the second uses photons.

It seems that the smaller the dispersion_samples, the darker the glass.   
Could this be the 2 missing dispersion samples making their absence felt?
_____________________________________________________________________

#include "consts.inc"
#include "transforms.inc"

#declare Test = sphere
{  y, 1
    pigment { rgbf 1 }
    finish
    {  reflection { 0 1 fresnel } conserve_energy
       specular 1 roughness 0.001
    }
    photons { target reflection on refraction on collect off }
    interior
    {  ior Crown_Glass_Ior dispersion Quartz_Glass_Dispersion
       #if (!PH) caustics 1 #end //PH is defined elsewhere
    }
}

union
{  object { Test interior { dispersion 1 } translate -3.6 * x }
    #declare T = 4;
    #while (T <= 8)
       #declare Samps = text
       {  ttf "arial.ttf" str(T,0,0) 0.01, 0 scale 0.6
          pigment { rgb x }
          no_shadow no_reflection
       }
       union
       {  object { Test interior { dispersion_samples T } }
          object { Samps Center_Trans (Samps, x) translate 2.25 * y }
          translate (T * 1.2 - 6) * x
       }
       #declare T = T + 2;
    #end
}

-- 
<Insert witty .sig here>

Post a reply to this message

Attachments:
Download 'dispersion_light.jpg' (51 KB) Download 'dispersion_light-ph.jpg' (52 KB)

Preview of image 'dispersion_light.jpg'

Preview of image 'dispersion_light-ph.jpg'

Personally, I'm not seeing anything, and I rendered the objects myself with the
latest beta. It might be nice if you included your global photon settings, and
perhaps the light source.  The problem might be differences in
viewing angle, angle of incidence, that kind of thing.

Try rendering each one from the same angle.  Rather than using a loop render the
scene as frames of an animation with your parameters tied to the frame_number.
Slice the images up and set each sphere side-by-side for comparison.

A.D.B.

"Cousin Ricky" <ric### [at] yahoocom> wrote:
> The leftmost sphere in each image has no dispersion.  The remaining
> spheres have dispersion_samples set to the number above each.  The first
> image uses faked caustics and the second uses photons.
>
> It seems that the smaller the dispersion_samples, the darker the glass.
> Could this be the 2 missing dispersion samples making their absence felt?
> _____________________________________________________________________
>
> #include "consts.inc"
> #include "transforms.inc"
>
> #declare Test = sphere
> {  y, 1
>     pigment { rgbf 1 }
>     finish
>     {  reflection { 0 1 fresnel } conserve_energy
>        specular 1 roughness 0.001
>     }
>     photons { target reflection on refraction on collect off }
>     interior
>     {  ior Crown_Glass_Ior dispersion Quartz_Glass_Dispersion
>        #if (!PH) caustics 1 #end //PH is defined elsewhere
>     }
> }
>
> union
> {  object { Test interior { dispersion 1 } translate -3.6 * x }
>     #declare T = 4;
>     #while (T <= 8)
>        #declare Samps = text
>        {  ttf "arial.ttf" str(T,0,0) 0.01, 0 scale 0.6
>           pigment { rgb x }
>           no_shadow no_reflection
>        }
>        union
>        {  object { Test interior { dispersion_samples T } }
>           object { Samps Center_Trans (Samps, x) translate 2.25 * y }
>           translate (T * 1.2 - 6) * x
>        }
>        #declare T = T + 2;
>     #end
> }
>
> --
> <Insert witty .sig here>

Post a reply to this message

"Anthony D. Baye" <Sha### [at] spamnomorehotmailcom> wrote:
> Personally, I'm not seeing anything, and I rendered the objects myself with the
> latest beta. It might be nice if you included your global photon settings, and
> perhaps the light source.  The problem might be differences in
> viewing angle, angle of incidence, that kind of thing.
>
> Try rendering each one from the same angle.  Rather than using a loop render the
> scene as frames of an animation with your parameters tied to the frame_number.
> Slice the images up and set each sphere side-by-side for comparison.
>
> "Cousin Ricky" <ric### [at] yahoocom> wrote:
> > It seems that the smaller the dispersion_samples, the darker the glass.
> > Could this be the 2 missing dispersion samples making their absence felt?

Top row was run with +kff5 declare=Ph=0 (faked caustics).
Bottom row was run with +kff5 declare=Ph=1 (photons).

Left half of each sphere has no dispersion; right half has dispersion_samples
set to the number in the frame.
_____________________________________________________________________

#ifndef (Ph) #declare Ph = no; #end

global_settings
{  assumed_gamma 1
   max_trace_level 256
   #if (Ph) photons { spacing 0.005 autostop 0 } #end
}

camera
{  location -5 * z
   right x up y
   angle 30
}

sky_sphere { pigment { gradient y color_map { [0 rgb 0.9] [1 rgb 0.5] } } }

light_source
{  <0, 1, -1> * 1000, rgb 1
   parallel point_at 0
}

plane { y, -1 pigment { rgb 1 } }

sphere
{  0, 1
   pigment { rgbf 1 }
   finish
   {  reflection { 0 1 fresnel } conserve_energy
      specular 1 roughness 0.001
   }
   interior
   {  ior 1.5
      #if (frame_number > 1)
         dispersion 1.05
         dispersion_samples frame_number * 2
      #end
      #if (!Ph) caustics 1 #end
   }
   photons { target reflection on refraction on collect off }
}

#if (frame_number > 1)
   text
   {  ttf "cyrvetic.ttf" str (frame_number * 2, 0, 0) 0.01, 0
      pigment { rgb x }
      no_shadow no_reflection
      scale 0.4
      translate <0.65, 0.65, -1>
   }
#end

Post a reply to this message

Attachments:
Download 'splice.png' (69 KB)

Preview of image 'splice.png'