POV-Ray : Newsgroups : povray.binaries.images : simple pattern with variation Server Time: 19 Feb 2019 23:58:10 GMT
  simple pattern with variation (Message 1 to 3 of 3)  
From: ingo
Subject: simple pattern with variation
Date: 15 Jan 2019 13:09:57
Message: <XnsA9D8901ACAC4Aseed7@news.povray.org>
A very simple pattern,
play with the blob thresholds to get fifferent patterns

ingo

---%<------%<------%<---
// Persistence of Vision Ray Tracer Scene Description File
// File: schakels.pov
// Vers: 3.7
// Desc: tiled pigment_pattern based on two blobs
// Date: 2019-01-14
// Auth: Ingo Janssen

#version 3.7;

global_settings {assumed_gamma 1}

camera {
  location <0,0,-12> look_at 0
  right x*image_width/image_height
}

//thresholds: 
#declare A=.65; #declare B=.65; #declare C=.65; #declare D=.65;
//#declare A=.75; #declare B=.45; #declare C=.65; #declare D=.65;
//#declare A=.45; #declare B=.45; #declare C=.85; #declare D=.85;
//#declare A=.65; #declare B=.85; #declare C=.85; #declare D=.65;
//#declare A=.55; #declare B=.55; #declare C=.55; #declare D=.55;
//#declare A=.75; #declare B=.75; #declare C=.55; #declare D=.55;
//#declare A=.65; #declare B=.45; #declare C=.85; #declare D=.3;

#declare P= pigment {
  pigment_pattern {
    object {
      union {
        blob {
          threshold A
          sphere {<.25,0.2,0>,.4,1}
          sphere {<.75,0.2,0>,.4,1}
        }
        blob {
          threshold B
          sphere {<.5,0.5,0>,.4,1}
          sphere {<.5,1.0,0>,.4,1}
        }
        blob {
          threshold C
          sphere {<.25,0.2,0>,.4,1}
          sphere {<.75,0.2,0>,.4,1}
          translate <0.55,0.55,0>
        }
        blob {
          threshold D
          sphere {<.5,0.5,0>,.4,1}
          sphere {<.5,1.0,0>,.4,1}
          translate <0.55,-0.55,0>
        }
        translate <-0.5,-0.2>
        scale <1/0.55,1/0.55,1>
      }
    }
    warp {repeat x flip x}
    warp {repeat y flip y}
  }
}

plane {
  z,0
  pigment {
    P
    pigment_map {
      [0.5, rgb 0]
      [0.5, rgb 1]
    }
  }
  finish {ambient 1}
}


Post a reply to this message


Attachments:
Download 'schakels.png' (67 KB)

Preview of image 'schakels.png'
schakels.png


 

From: Bald Eagle
Subject: Re: simple pattern with variation
Date: 16 Jan 2019 04:35:02
Message: <web.5c3eb46c9f189ee0765e06870@news.povray.org>
ingo <ing### [at] tagpovrayorg> wrote:
> A very simple pattern,
> play with the blob thresholds to get fifferent patterns
>
> ingo

Nice!  :)
I ought to make the parameters clock-dependent and run it as an animation like I
did with Tek's overlapping patterns.

Thanks for sharing   :)


Post a reply to this message

From: Paolo Gibellini
Subject: Re: simple pattern with variation
Date: 16 Jan 2019 09:18:37
Message: <5c3ef6ed$1@news.povray.org>
ingo wrote on 15/01/2019 14:09:
> A very simple pattern,
> play with the blob thresholds to get fifferent patterns
> 
> ingo

Simple but cool!
Paolo


Post a reply to this message

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.