|
 |
> i dont get it or the help file is inconclusive !!
>
> AXIS_1_VECTOR, AXIS_2_VECTOR, Size_1, Size_2
>
> referring to "size"
> "There is no point in using circular with linear area lights or area lights
> which have a 2x2 size."
> .. .
> .. . that's already circular.
> suggesting "size" = n lights.
> and the vector length = array dimensions
>
> so I'm still not sure, also it to alludes to adaptive n = n lights.
>
>
AXIS_1_VECTOR, AXIS_2_VECTOR define the extent or dimention of the area
light.
Size_1, Size_2 define how many samples or sub-light are used to evaluate
the penumbra.
The samples are evenly spaced along the extent.
When using circular, the array of samples is squashed from it's
rectangular shape into a circular one. A 2x2 area light is always square.
This sample illustrate the principle of circular VS. regular area_light :
//*************** START *************
#version 3.7;
// render as a square image
// +w1024 +h1024
// +w800 +h800
global_settings{assumed_gamma 1}
plane{-z, -10 pigment{ rgb 1}finish{brilliance 0} }
disc{0,z,10000,0.03}// Mask with a small hole
#declare W=11; // How wide the area light is
#declare N=17; // The number of samples to use
light_source{-10*z rgb<1,0,1>*pow(N,2) area_light W*x W*y N N circular }
// Use pow(N,2) to make the light bright enough to always be seen.
// The intensity is distributed along all the sub-lights.
light_source{-10*z rgb<0,1,0>*pow(N,2) area_light W*x W*y N N }
camera{orthographic location 1*z look_at 10*z up W/2+1.2 right W/2+1.2}
//********** END ***********
It's simply an area_light shining through an opening that is
intentionally much to small to show the samples pattern.
If you add adaptive, it will show the initial array that will be used.
adaptive 0 start with a 2x2 array
adaptive 1 start with a 3x3 array
adaptive 2 start with a 5x5 array
adaptive 3 start with a 9x9 array
Adaptive only improve performance if the area light have at least twice
the number of samples than the mi minimal array used.
Alain
Post a reply to this message
|
|
|
|
> adaptive 0 is still 2x2 (at least)
> adaptive 0 does not mean off.
> apparently
>
>
>
The only way to turn adaptive OFF is to NOT use the adaptive key word.
In adaptive N, the initial number of samples is :
2^N+1
2^0=1 +1 =2
2^1=2 +1 =3
2^2=4 +1 =5
2^3=8 +1 =9
...
Also, the actual number of samples will follow that same pattern and
will use the smallest number of samples that is AT LEAST the requested
number.
area_light x z 4 4 adaptive 0
will actually use a 5x5 array.
area_light x z 6 6 adaptive 0
will use 9x9.
Post a reply to this message
|
|
