POV-Ray : Newsgroups : povray.binaries.images : High Glen - take #3 (final) Server Time: 23 Jul 2019 11:33:39 GMT
  High Glen - take #3 (final) (Message 1 to 10 of 25)  
Goto Latest 10 Messages Next 10 Messages >>>
From: Thomas de Groot
Subject: High Glen - take #3 (final)
Date: 10 May 2019 06:57:21
Message: <5cd520d1@news.povray.org>
Last February, I presented some early renders of this scene. It has now 
been "finished" (my scenes are never finished).

-- 
Thomas


Post a reply to this message


Attachments:
Download 'high glen_final.jpg' (652 KB)

Preview of image 'high glen_final.jpg'
high glen_final.jpg


 

From: William F Pokorny
Subject: Re: High Glen - take #3 (final)
Date: 10 May 2019 13:07:54
Message: <5cd577aa$1@news.povray.org>
On 5/10/19 2:57 AM, Thomas de Groot wrote:
> Last February, I presented some early renders of this scene. It has now 
> been "finished" (my scenes are never finished).
> 
I like the atmosphere/mood.

Supposing the individual is using a variation of an Alphorn?

Bill P.


Post a reply to this message

From: clipka
Subject: Re: High Glen - take #3 (final)
Date: 10 May 2019 14:20:33
Message: <5cd588b1$1@news.povray.org>
Am 10.05.2019 um 15:07 schrieb William F Pokorny:
> Supposing the individual is using a variation of an Alphorn?

Looks like a lur to me.


Post a reply to this message

From: William F Pokorny
Subject: Re: High Glen - take #3 (final)
Date: 10 May 2019 14:27:43
Message: <5cd58a5f@news.povray.org>
On 5/10/19 10:20 AM, clipka wrote:
> Am 10.05.2019 um 15:07 schrieb William F Pokorny:
>> Supposing the individual is using a variation of an Alphorn?
> 
> Looks like a lur to me.

Thanks and yes more likely. The Lur is a new instrument to me.

Bill P.


Post a reply to this message

From: Norbert Kern
Subject: Re: High Glen - take #3 (final)
Date: 10 May 2019 15:55:01
Message: <web.5cd59e6a2ad5c3dd3c1c78400@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
> Last February, I presented some early renders of this scene. It has now
> been "finished" (my scenes are never finished).
>
> --
> Thomas



The sky is really nice - how did you made it?

Regards,
Norbert


Post a reply to this message

From: Cousin Ricky
Subject: Re: High Glen - take #3 (final)
Date: 10 May 2019 19:12:02
Message: <5cd5cd02$1@news.povray.org>
On 2019-05-10 2:57 AM (-4), Thomas de Groot wrote:
> Last February, I presented some early renders of this scene. It has now 
> been "finished" (my scenes are never finished).

Is this related to your Mistborn series?


Post a reply to this message

From: Ton
Subject: Re: High Glen - take #3 (final)
Date: 11 May 2019 00:35:00
Message: <web.5cd618af2ad5c3dd15b36e3c0@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
> Last February, I presented some early renders of this scene. It has now
> been "finished" (my scenes are never finished).
>
> --
> Thomas

Good atmosphere, some guard welcoming the new morning.
One day I'll finish a scene!

Cheers
Ton.


Post a reply to this message

From: Thomas de Groot
Subject: Re: High Glen - take #3 (final)
Date: 11 May 2019 06:52:38
Message: <5cd67136$1@news.povray.org>
On 10-5-2019 16:27, William F Pokorny wrote:
> On 5/10/19 10:20 AM, clipka wrote:
>> Am 10.05.2019 um 15:07 schrieb William F Pokorny:
>>> Supposing the individual is using a variation of an Alphorn?
>>
>> Looks like a lur to me.
> 
> Thanks and yes more likely. The Lur is a new instrument to me.
> 
> Bill P.

It is indeed a lur.

-- 
Thomas


Post a reply to this message

From: Thomas de Groot
Subject: Re: High Glen - take #3 (final)
Date: 11 May 2019 07:06:23
Message: <5cd6746f@news.povray.org>
On 10-5-2019 17:53, Norbert Kern wrote:
> Thomas de Groot <tho### [at] degrootorg> wrote:
>> Last February, I presented some early renders of this scene. It has now
>> been "finished" (my scenes are never finished).
>>
>> --
>> Thomas
> 
> 
> 
> The sky is really nice - how did you made it?
> 
> Regards,
> Norbert
> 
> 

Three elements compose the sky (and atmosphere) from base to top:
1) a ground fog, slightly tilted to fill the distant valleys more);
2) An atmospheric haze;
3) a cloud layer.

All three are made up of non-interpenetrating media. The code looks like 
this (watch out for unwanted line feeds!):

//--start code------------------------------------------
#if (Atmos)
// An atmosphere composed of a ground fog and an haze:

#local Murkiness = 1.5; //best somewhere between 0.5 and 2.9 approximately

#local GroundFog =
difference {
   sphere {<0,0,0>, 6.0}
   plane {<0,1,0>, 0.0}
   scale <1, 0.14/6, 1>
   //scale 5000
   rotate -1.5*x
}
//----------------------------------------
#if (Debug)
#declare Min = min_extent(GroundFog);
#declare Max = max_extent(GroundFog);
#debug concat("\n  min_extent GroundFog: <",vstr(3, Min, ", ", 0,3),">\n")
#debug concat("  max_extent GroundFog: <",vstr(3, Max, ", ", 0,3),">\n\n")
#end
//----------------------------------------

#local Haze =
difference {
   sphere {<0,0,0>, 6.0}
   plane {<0,1,0>, 0.0}
   scale <1, 0.15/6, 1>
   //scale 5000
   rotate -1.5*x
   translate 0.14002*y
}
//----------------------------------------
#if (Debug)
#declare Min = min_extent(Haze);
#declare Max = max_extent(Haze);
#debug concat("\n  min_extent Haze: <",vstr(3, Min, ", ", 0,3),">\n")
#debug concat("  max_extent Haze: <",vstr(3, Max, ", ", 0,3),">\n\n")
#end
//----------------------------------------

#declare Atmosphere =
union {
   object {
     GroundFog
     hollow
     pigment {rgb <1,1,1> transmit 1.0}
     interior {
       media {
         scattering {5 rgb <0.6, 0.6, 0.8>*Murkiness/5000 extinction 1.0
           eccentricity 0.01
         }
         samples 20
         density {
           spherical
           density_map {
             [0.00 rgb 0.1]
             [0.45 rgb 1.0]
             [0.50 rgb 0.1]
             [0.60 rgb 0.1]
             [0.65 rgb 0.9]
             [1.00 rgb 1.0]
           }
           scale 11
           warp {turbulence <2.0, 3.0, 2.0>}
           scale <1.0, 1.0, 2.0>
           scale 1/11
         }
       }
     }
     scale 5000
     translate <CamLoc.x, 0.0, CamLoc.z>
   }
   object {
     Haze
     hollow
     pigment {rgb <1,1,1> transmit 1.0}
     interior {
       media {
         scattering {5, rgb <1,1,1>*0.10/5000
           eccentricity 0.4
         }
         samples 20
         density {
           spherical
           density_map {
             [0.00 rgb 1.0]
             [0.90 rgb 0.0]
           }
         }
       }
     }
     scale 5000
     translate <CamLoc.x, 0.0, CamLoc.z>
   }
} //end of Atmosphere union

//----------------------------------------
#if (Debug)
#declare Min = min_extent(Atmosphere);
#declare Max = max_extent(Atmosphere);
#debug concat("\n  min_extent Atmosphere: <",vstr(3, Min, ", ", 0,3),">\n")
#debug concat("  max_extent Atmosphere: <",vstr(3, Max, ", ", 0,3),">\n\n")
#end
//----------------------------------------

Atmosphere
#end  //of Atmos

//--------------------------------------------------
#if (Clouds)
#local CloudScale = 1000*10;

#declare Density_in =
density {
	wrinkles
	frequency 4
   color_map {
     [0.30 rgb <0.00, 0.00, 0.00>]
     [0.48 rgb 0.9]
     [0.52 rgb 0.9]
     [0.70 rgb <0.00, 0.00, 0.00>]
   }
   scale 0.5
	//rotate 90*x	//when using spirals; either here or:
   scale 30
   warp {turbulence <3, 4, 2>*0.9}
   scale 1/30
	//rotate 90*x	//when using spirals; here
}

#declare Density_out =
density {
     rgb <0.00, 0.00, 0.00>
}

#declare CloudScape =
   difference {
     sphere {0, 1.0}
     sphere {0, 0.75}
     hollow
     material {
       texture {pigment {rgb 1 transmit 1.0} finish {ambient 0 diffuse 0}}
       interior {
         media {
           // (---general values---)
           intervals 1
           samples 50
           //absorption rgb <0.5, 0.5, 0.5>*0.00001/CloudScale
           scattering {1, rgb <1, 1, 1>*8.00/CloudScale}

           // (---density---)
           density {
             spherical
			  	  density_map {
			  	    [0.1 Density_out]
				      [0.9 Density_in]
				    }
				    warp {turbulence 0.3}
			  	  scale 1
           }
         }
       }
     }
   scale CloudScale
   scale <5, 1.0, 5>
	rotate -20*z
   rotate 15*y
   translate <CamLookAt.x, CamLoc.y, 0>
   }

CloudScape
#end  //of Clouds
//--end code------------------------------------------


-- 
Thomas


Post a reply to this message

From: Thomas de Groot
Subject: Re: High Glen - take #3 (final)
Date: 11 May 2019 07:09:22
Message: <5cd67522@news.povray.org>
On 10-5-2019 21:12, Cousin Ricky wrote:
> On 2019-05-10 2:57 AM (-4), Thomas de Groot wrote:
>> Last February, I presented some early renders of this scene. It has 
>> now been "finished" (my scenes are never finished).
> 
> Is this related to your Mistborn series?

Wow! you have an excellent memory! ;-)
In reality, the Mistborn series has been a bit still-born I am afraid, 
in so far that I have not been able to do something really serious about 
it. But, yes, now that you mention it, I think this scene could very 
well be included into the series. Thanks for reminding me!

-- 
Thomas


Post a reply to this message

Goto Latest 10 Messages Next 10 Messages >>>

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.