POV-Ray : Newsgroups : povray.binaries.images : Apparent circular pattern of scratches Server Time
29 Mar 2024 08:55:58 EDT (-0400)
  Apparent circular pattern of scratches (Message 8 to 17 of 17)  
<<< Previous 7 Messages Goto Initial 10 Messages
From: Thomas de Groot
Subject: Re: Apparent circular pattern of scratches
Date: 26 Jan 2019 07:10:38
Message: <5c4c4e3e@news.povray.org>
... and fulling following "The Teachings of Clipka" (Scroll 24F, Chapter 
"On Metals and their Finish").

-- 
Thomas


Post a reply to this message


Attachments:
Download 'circular scratches_test.png' (519 KB)

Preview of image 'circular scratches_test.png'
circular scratches_test.png


 

From: ingo
Subject: Re: Apparent circular pattern of scratches
Date: 26 Jan 2019 08:10:48
Message: <XnsA9E3903F11149seed7@news.povray.org>
in news:5c4c20b9@news.povray.org Thomas de Groot wrote:

> Proof of concept using different finishes for surface and scratches. 
> Still in flux...
> 

The scratches are based on the random sticks? If so, try uses extremely 
stretched boxes as sticks to get a sharper 'impression'.

Maybe use a gradient 'depth map' texture on the sticks, the scratichg edge 
rgb 1 and going to rgb 0 to the other edges. Vary the rgb 1 on the sharp 
edge for depth variation. 
 
Render it with orthocam and a light at the camera location.

ingo


Post a reply to this message

From: Norbert Kern
Subject: Re: Apparent circular pattern of scratches
Date: 26 Jan 2019 09:15:01
Message: <web.5c4c6ae05e3f44501fbfafc10@news.povray.org>
Hello,

here is my attempt, using a layered texture and an imagefile for the scratches
(similar to what Thomas posted here -
http://news.povray.org/povray.advanced-users/message/%3C5c4970bb%40news.povray.org%3E/#%3C5c4970bb%40news.povray.org%3E
).


material {
        texture {
                pigment {color srgb <0.9284,0.9016,0.8678>}
  normal {
                        average
                        normal_map {
                                [1      bump_map {png "scratches"}
                                        bump_size -1
                                ]
                                [1      bump_map {png "scratches"}
                                        bump_size -1
                                        rotate x*90
                                ]
                                [1      bump_map {png "scratches"}
                                        bump_size -1
                                        rotate z*90
                                ]
                        }
                        accuracy 0.003
                }
                finish {
                        ambient 0
                        diffuse 0.1
                        specular 1
                        roughness 0.0003
                 phong 0.5
                        phong_size 10
                        brilliance 3
                        reflection {0.6, 1 fresnel on metallic}
                        conserve_energy
                }
        }
        texture {
  pigment {color srgbf <0.96,0.965,0.975,0.99/0.8>*0.8}
  finish {
          ambient 0
          diffuse 0.05
          reflection {0, 1 fresnel on}
          conserve_energy
          specular albedo 0.5
                        roughness 0.001
                        brilliance 7
                }
 }
        interior {ior 3.64}
        scale 1
 Reorient_Trans (z, 1)
}

Norbert


Post a reply to this message


Attachments:
Download 'scratch finish on metallic surfacea.jpg' (684 KB)

Preview of image 'scratch finish on metallic surfacea.jpg'
scratch finish on metallic surfacea.jpg


 

From: clipka
Subject: Re: Apparent circular pattern of scratches
Date: 26 Jan 2019 09:40:01
Message: <5c4c7141$1@news.povray.org>
Am 26.01.2019 um 09:56 schrieb Thomas de Groot:
> Proof of concept using different finishes for surface and scratches. 
> Still in flux...

I think we're getting somewhere.


Post a reply to this message

From: omniverse
Subject: Re: Apparent circular pattern of scratches
Date: 26 Jan 2019 13:55:03
Message: <web.5c4cac675e3f44509c5d6c810@news.povray.org>
"Norbert Kern" <nor### [at] t-onlinede> wrote:
> Hello,
>
> here is my attempt, using a layered texture and an imagefile for the scratches
> (similar to what Thomas posted here -
>
http://news.povray.org/povray.advanced-users/message/%3C5c4970bb%40news.povray.org%3E/#%3C5c4970bb%40news.povray.org%
3E
> ).
>
>
> material {
>         texture {
>                 pigment {color srgb <0.9284,0.9016,0.8678>}
>   normal {
>                         average
>                         normal_map {
>                                 [1      bump_map {png "scratches"}
>                                         bump_size -1
>                                 ]
>                                 [1      bump_map {png "scratches"}
>                                         bump_size -1
>                                         rotate x*90
>                                 ]
>                                 [1      bump_map {png "scratches"}
>                                         bump_size -1
>                                         rotate z*90
>                                 ]
>                         }
>                         accuracy 0.003
>                 }
>                 finish {
>                         ambient 0
>                         diffuse 0.1
>                         specular 1
>                         roughness 0.0003
>                  phong 0.5
>                         phong_size 10
>                         brilliance 3
>                         reflection {0.6, 1 fresnel on metallic}
>                         conserve_energy
>                 }
>         }
>         texture {
>   pigment {color srgbf <0.96,0.965,0.975,0.99/0.8>*0.8}
>   finish {
>           ambient 0
>           diffuse 0.05
>           reflection {0, 1 fresnel on}
>           conserve_energy
>           specular albedo 0.5
>                         roughness 0.001
>                         brilliance 7
>                 }
>  }
>         interior {ior 3.64}
>         scale 1
>  Reorient_Trans (z, 1)
> }
>
> Norbert

I like that, fine scratches or scuffed. Great how it follows the curvatures and
reflected light.

Any criticism I can think of would be that some lines appear to radiate outward
from the lit areas, showing up as bright as the other, non-radial lines. Which
is what was mentioned before about the original idea, so I wonder how that
directional condition could be achieved? Seems like a polarization effect needed
to do that anyhow.


Post a reply to this message

From: Bald Eagle
Subject: Re: Apparent circular pattern of scratches
Date: 26 Jan 2019 15:05:01
Message: <web.5c4cbc425e3f4450765e06870@news.povray.org>
"omniverse" <omn### [at] charternet> wrote:
> "Norbert Kern" <nor### [at] t-onlinede> wrote:
> > Hello,
> >
> > here is my attempt, using a layered texture and an imagefile for the scratches

.....

> > Norbert

Holy crap.  :O



> I like that, fine scratches or scuffed. Great how it follows the curvatures and
> reflected light.


I think that's an important part of the effect - the halo of concentric
scratches.


> Any criticism I can think of would be that some lines appear to radiate outward
> from the lit areas, showing up as bright as the other, non-radial lines. Which
> is what was mentioned before about the original idea, so I wonder how that
> directional condition could be achieved? Seems like a polarization effect needed
> to do that anyhow.



Yeah - I'm also still very curious as to what gives rise to that selective
effect IRL.  I'd be tempted to predict that only a series of oriented lines
would reflect strongly - not a circular pattern.  I mean, it's not like
completely random scratches adopt a circular pattern - so it must necessarily be
a purely optical effect.


Post a reply to this message

From: Thomas de Groot
Subject: Re: Apparent circular pattern of scratches
Date: 27 Jan 2019 02:37:49
Message: <5c4d5fcd$1@news.povray.org>
On 26-1-2019 14:10, ingo wrote:
> in news:5c4c20b9@news.povray.org Thomas de Groot wrote:
> 
>> Proof of concept using different finishes for surface and scratches.
>> Still in flux...
>>
> 
> The scratches are based on the random sticks? If so, try uses extremely
> stretched boxes as sticks to get a sharper 'impression'.

No, on a bump_map. Not a very subtle one I must say but sufficient for 
the purpose.

> 
> Maybe use a gradient 'depth map' texture on the sticks, the scratichg edge
> rgb 1 and going to rgb 0 to the other edges. Vary the rgb 1 on the sharp
> edge for depth variation.

That is a good alternative for making scratch maps, apart from simply 
downloading them from the web :-)

>   
> Render it with orthocam and a light at the camera location.
> 
> ingo
> 


-- 
Thomas


Post a reply to this message

From: Thomas de Groot
Subject: Re: Apparent circular pattern of scratches
Date: 27 Jan 2019 02:52:48
Message: <5c4d6350@news.povray.org>
On 26-1-2019 21:00, Bald Eagle wrote:
> "omniverse" <omn### [at] charternet> wrote:
>> "Norbert Kern" <nor### [at] t-onlinede> wrote:
>>> Hello,
>>>
>>> here is my attempt, using a layered texture and an imagefile for the scratches
> 
> .....
> 
>>> Norbert
> 
> Holy crap.  :O

I agree. The important thing is to use a bump_map of some quality.

> 
> 
> 
>> I like that, fine scratches or scuffed. Great how it follows the curvatures and
>> reflected light.
> 
> 
> I think that's an important part of the effect - the halo of concentric
> scratches.

See image attached. Playing with different bump_maps and strength of the 
bump_size.

> 
> 
>> Any criticism I can think of would be that some lines appear to radiate outward
>> from the lit areas, showing up as bright as the other, non-radial lines. Which
>> is what was mentioned before about the original idea, so I wonder how that
>> directional condition could be achieved? Seems like a polarization effect needed
>> to do that anyhow.

Maybe, that comes from the fact that the scratches are not very linear, 
more "curvy" as it were. I noticed that also with different bump_maps. 
The more linear the scratches are, the more the effect is visible.

> 
> 
> 
> Yeah - I'm also still very curious as to what gives rise to that selective
> effect IRL.  I'd be tempted to predict that only a series of oriented lines
> would reflect strongly - not a circular pattern.  I mean, it's not like
> completely random scratches adopt a circular pattern - so it must necessarily be
> a purely optical effect.
> 

It /is/ an optical effect of course, based imho on the strength of 
incident light reflecting from the scratch surfaces. The closer the 
incident light angle is to 90 degrees with regard to (part of) the 
scratch surface, the stronger the scratch reflects. Inversely, the 
scratch will hardly or not light up when the incident light angle is 
very low. The cumulation of strongly reflecting scratches will dominate 
the view in the end, giving rise to the optical illusion.

-- 
Thomas


Post a reply to this message


Attachments:
Download 'circular scratches_test.png' (427 KB)

Preview of image 'circular scratches_test.png'
circular scratches_test.png


 

From: Norbert Kern
Subject: Re: Apparent circular pattern of scratches
Date: 27 Jan 2019 07:15:01
Message: <web.5c4d9ffb5e3f44501fbfafc10@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:

> I agree. The important thing is to use a bump_map of some quality.

I found a povray file to get the bump_map. Perhaps somebody knows the origin. My
only contribution is an aoi texture as default.


//------------------------
/* scratches2 */
// +fn16 Output_File_Name=d:\images\ +w4096 +h4096

#version 3.7;

global_settings {
        #declare a_g = 2.2;
        assumed_gamma a_g
        max_trace_level 16
        noise_generator 3
}

camera {
        orthographic
        location -5*z
        look_at 0
        right 40*x
        up 40*y
}

/*#default {
        texture {
                pigment {
                        bozo
                        scale 0.2
                        color_map {
                                [0      rgb 0.5]
                                [1      rgb 1]
                        }
                }
                finish {ambient 1}
        }
}*/
#default {
        texture {
                pigment {
                        aoi
                        color_map {
                                [0      srgb 1]
                                [0.5    srgb 0]
                                [1      srgb 1]
                        }
                }
                finish {ambient 1}
        }
}


#include "transforms.inc"

#declare I = seed (1);
#declare ang = 0;
#while (ang < 360)
        #declare num = 20+20*rand (I);
        #declare i = 0;
        #while (i < num)
                #declare px = no;
                #declare nx = no;
                #declare r = 0.01+0.035*rand (I);
                #declare s = 2+10*rand (I);
                #declare _x = -20+40*rand (I);
                #declare _y = -20+40*rand (I);
                sphere {
                        0, 1
                        scale <r,0.5,r>
                        scale <1,s,1>
                        rotate ang*z
                        translate <_x,_y,0>
                }
                #if (vtransform (0.5*y, transform {scale <1,s,1> rotate ang*z
translate _x*x}).x > 40 | vtransform (-0.5*y, transform {scale <1,s,1> rotate
ang*z translate _x*x}).x > 40)
                        #declare px = yes;
                        sphere {
                                0, 1
                                scale <r,0.5,r>
                                scale <1,s,1>
                                rotate ang*z
                                translate <_x-40,_y,0>
                        }
                #else
                        #if (vtransform (0.5*y, transform {scale <1,s,1> rotate
ang*z translate _x*x}).x < 40 | vtransform (-0.5*y, transform {scale <1,s,1>
rotate ang*z translate _x*x}).x < 40)
                                #declare nx = yes;
                                sphere {
                                        0, 1
                                        scale <r,0.5,r>
                                        scale <1,s,1>
                                        rotate ang*z
                                        translate <_x+40,_y,0>
                                }
                        #end
                #end
                #if (vtransform (0.5*y, transform {scale <1,s,1> rotate ang*z
translate _y*y}).y > 40 | vtransform (-0.5*y, transform {scale <1,s,1> rotate
ang*z translate _y*y}).y > 40)
                        sphere {
                                0, 1
                                scale <r,0.5,r>
                                scale <1,s,1>
                                rotate ang*z
                                translate <_x,_y-40,0>
                        }
                        #if (px)
                                sphere {
                                        0, 1
                                        scale <r,0.5,r>
                                        scale <1,s,1>
                                        rotate ang*z
                                        translate <_x-40,_y-40,0>
                                }
                        #else
                                #if (nx)
                                        sphere {
                                                0, 1
                                                scale <r,0.5,r>
                                                scale <1,s,1>
                                                rotate ang*z
                                                translate <_x+40,_y-40,0>
                                        }
                                #end
                        #end
                #else
                        #if (vtransform (0.5*y, transform {scale <1,s,1> rotate
ang*z translate _y*y}).y < 40 | vtransform (-0.5*y, transform {scale <1,s,1>
rotate ang*z translate _y*y}).y < 40)
                                sphere {
                                        0, 1
                                        scale <r,0.5,r>
                                        scale <1,s,1>
                                        rotate ang*z
                                        translate <_x,_y+40,0>
                                }
                                #if (px)
                                        sphere {
                                                0, 1
                                                scale <r,0.5,r>
                                                scale <1,s,1>
                                                rotate ang*z
                                                translate <_x-40,_y+40,0>
                                        }
                                #else
                                        #if (nx)
                                                sphere {
                                                        0, 1
                                                        scale <r,0.5,r>
                                                        scale <1,s,1>
                                                        rotate ang*z
                                                        translate
<_x+40,_y+40,0>
                                                }
                                        #end
                                #end
                        #end
                #end
                #declare i = i+1;
        #end
        #declare ang = ang+20;
#end

//--------------


Norbert


Post a reply to this message

From: Thomas de Groot
Subject: Re: Apparent circular pattern of scratches
Date: 28 Jan 2019 02:36:04
Message: <5c4eb0e4$1@news.povray.org>
On 27-1-2019 13:11, Norbert Kern wrote:
> Thomas de Groot <tho### [at] degrootorg> wrote:
> 
>> I agree. The important thing is to use a bump_map of some quality.
> 
> I found a povray file to get the bump_map. Perhaps somebody knows the origin. My
> only contribution is an aoi texture as default.
> 

Ah! Thank you indeed. For a moment I thought it could be Steve Paget as 
I have a bump_map with that name from him, but that is a very different 
image, not related. The question remains unanswered for now.

-- 
Thomas


Post a reply to this message

<<< Previous 7 Messages Goto Initial 10 Messages

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.