|
 |
On 06/29/2014 04:22 PM, Stephen wrote:
>
> No thank you. It reminds me of Op Art. :-)
>
Wasn't aiming for Op Art, but agree it sort of falls into that category.
Given your mention, aiming for Op Art using functions in the attached
code and image. Unsure if anything in the end, but fun to try.
Bill P.
//------------------------
global_settings { assumed_gamma 1.0 ambient_light srgb <1.0,1.0,1.0> }
#declare White = srgbft <1.0,1.0,1.0,0.0,0.0>;
background { color White }
#declare Camera00 = camera {
orthographic
location <0.0,0.0,-10.001>
sky <0.0,1.0,0.0>
angle 35.0
right x*(image_width/image_height)
look_at <0.0,0.0,0.0>
}
// Credit: Alex Kluchikov as these functions started with his
// curles examples.
#include "functions.inc"
#declare FnctTarget = function { pattern{spiral1 7} }
#declare FnctFlipDir = function (x,y,z) {
FnctTarget(y/(1/8),x/(1/8),z)
}
#declare FnctPigment = function (x,y,z) {
(cos(FnctTarget(x,y,z)*8*pi+FnctFlipDir(x,y,z)*2*pi)+1)
*(1/2)*(1-FnctTarget(x,y,z))
}
#declare Black = srgbft <0.0,0.0,0.0,0.0,0.0>;
#declare Aqua = srgbft <0.6314,0.8549,0.8431,0.0,0.0>;
#declare ColorMap0 = color_map { [ 0.0 Black ] [ 1.0 Aqua ] }
#declare Pigment0 = pigment {
function { FnctPigment(x,y,z) }
color_map { ColorMap0 }
}
#declare Finish0 = finish { ambient srgb <1,1,1> diffuse 0.0 }
#declare Texture0 = texture { pigment { Pigment0 } finish { Finish0 } }
#declare Plane0 = plane { <0.0,0.0,1.0>, 0.0 }
#declare Object0 = object { object { Plane0 } texture { Texture0 } }
camera { Camera00 }
object { Object0 }
//------------------------
Post a reply to this message
Attachments:
Download 'tryatopart.jpg' (567 KB)
Preview of image 'tryatopart.jpg'
|
|
