This made with three concentric spheres:

* The innermost sphere has a radius of 6000 units and has the land and 
ocean texture.

* The middle sphere has a radius of 6009 units, textured with a granite 
map that is highly perturbed (lambda = 4).  The color map is clear to 
.66, fading to full white at .67.

* The outermost sphere has a radius of 6010 units and is transparent 
with a scattering media in the interior.

The scattering media and the clouds texture do a fair job of hiding the 
lameness of the land texturing.

Regards,
John

Post a reply to this message

Attachments:
Download 'planet.png' (209 KB)

Preview of image 'planet.png'

Yes, it needs polar ice caps.

Regards,
John

Post a reply to this message

Am 28.03.2013 05:23, schrieb John VanSickle:
> Yes, it needs polar ice caps.

Does it?

Post a reply to this message

John VanSickle <evi### [at] KOSHERhotmailcom> wrote:
> This made with three concentric spheres:
>
> * The innermost sphere has a radius of 6000 units and has the land and
> ocean texture.
>
> * The middle sphere has a radius of 6009 units, textured with a granite
> map that is highly perturbed (lambda = 4).  The color map is clear to
> .66, fading to full white at .67.
>
> * The outermost sphere has a radius of 6010 units and is transparent
> with a scattering media in the interior.
>
> The scattering media and the clouds texture do a fair job of hiding the
> lameness of the land texturing.
>
> Regards,
> John

would you mind posting the code for the planet?  I'd like to fiddle with the
landmasses and use it in my jumpgate scene.

Regards,
A.D.B.

Post a reply to this message

On 28-3-2013 5:23, John VanSickle wrote:
> Yes, it needs polar ice caps.

Looking very good indeed. A greenhouse planet obviously; the way we are 
going ourselves ;-)

Thomas

Post a reply to this message

This is looking nice already.

The clouds are the most obvious fakeness as they are distributed
randomly and not according to realistic weather patterns. Unfortunately
this is really hard to do (my clouds looked worse when I tried this).

Also you are probably aware that on a photograph you would not
see stars or detail beyond the terminator. Of course people might
intentionally use multiple exposures for this so all is well ;)

Post a reply to this message

On 3/28/2013 3:03 AM, Anthony D. Baye wrote:

> would you mind posting the code for the planet?  I'd like to fiddle with the
> landmasses and use it in my jumpgate scene.

Hope this helps,
John

//--- start of planet03.inc

#ifndef(PlanetTrans)
   #local PlanetTrans = transform { }
#end

#local textOcean = texture {
   pigment { rgb <0,.01,.04>}
   finish { diffuse 1 ambient 0 specular .125 roughness .02 }
}

#local textLand = texture {
   pigment { granite
     pigment_map {
       [.7 granite translate y*5
         color_map {
           [.5 rgb <.125,.2,.1> ]
           [.5 rgb <.35,.3,.25> ]
         }
       ]
       [.8  rgb <.125,.1,.075> ]
     }
   }
   normal { granite
     normal_map {
       [.7 granite .01 ]
       [.8 granite 1 scale .01]
     }
   }
}

union {
   sphere { 0,1
     texture {
       granite
       texture_map {
         [.5 textOcean]
         [.5 textLand]
       }
       scale 3
     }
     scale 6e3
   }

   sphere { 0,1 hollow
     texture {  pigment { rgbt <1,1,1,1> } }
     interior {
       media { scattering { 2, <.2,.6,1>*.01 } }
     }
     scale 6010
   }

   sphere { 0,1 hollow
     texture {
       pigment { granite turbulence 1 lambda 4
         color_map {
           [.65 rgbt 1]
           [.66 rgb 1]
         }
       }
       finish { ambient 0 diffuse 1 }
     }
     scale 6009
   }

   transform PlanetTrans
}

//--- end of planet03.inc

Post a reply to this message

John VanSickle <evi### [at] KOSHERhotmailcom> wrote:
> On 3/28/2013 3:03 AM, Anthony D. Baye wrote:
>
> > would you mind posting the code for the planet?  I'd like to fiddle with the
> > landmasses and use it in my jumpgate scene.
>
> Hope this helps,
> John
>

Thanks!

Regards,
A.D.B.

Post a reply to this message