Hi all:

     I finally found a simple way to create an endless stream of 
wallpapers for my virtual rooms, using the new tiling pattern type 5 
(thanks, clipka!), combined with repeat warps in a texture_map.

     Here are a few samples attached. For these I used a William Morris 
wallpaper design as input, but almost anything can be used (including 
procedural textures, of course).

     If you enjoy repetition, try the following code at your own risk... ;)

--
Jaime


// +w665 +h768
#version 3.7;

// change the seed until you find a nice result (shouldn't take more 
than a few tries)
#declare r_pattern=seed(745);

// name of the PNG image to be used as a base
// the URL below doesn't works obviously, is just a recommended image source
#declare 
imagemap="http://upload.wikimedia.org/wikipedia/commons/e/ed/Morris_Snakeshead_printed_textile_1876_v_2.jpg"

// and the desired scale for it...
#declare im_scale=5;

// create the random base texture
#declare t_base=
texture{
     pigment{
       image_map{jpeg imagemap interpolate 2}
       rotate 90*x
       translate rand(r_pattern)*x
       translate rand(r_pattern)*z
       rotate 360*rand(r_pattern)*y
       scale im_scale
       warp { repeat .5*x flip x}
       warp { repeat sqrt(.75)*z flip z}
     }
     finish{emission 1}
}

// tiling
plane{z,1
    texture{
     pigment_pattern{tiling 5}
     texture_map{
       [0   t_base rotate -120*y]
       [1/3 t_base rotate -120*y]
       [1/3 t_base]
       [2/3 t_base]
       [2/3 t_base rotate 120*y]
       [1.0 t_base rotate 120*y]
     }
     rotate -90*x
    }
}

// render it seamless
camera{
    orthographic
    up 6/sqrt(.75)*y
    right 6*x
}

Post a reply to this message

Attachments:
Download 'wpgen-t5-im_morris_snakeshead-01.jpg' (199 KB) Download 'wpgen-t5-im_morris_snakeshead-02.jpg' (202 KB) Download 'wpgen-t5-im_morris_snakeshead-03.jpg' (217 KB) Download 'wpgen-t5-im_morris_snakeshead-04.jpg' (210 KB)

Preview of image 'wpgen-t5-im_morris_snakeshead-01.jpg'

Preview of image 'wpgen-t5-im_morris_snakeshead-02.jpg'

Preview of image 'wpgen-t5-im_morris_snakeshead-03.jpg'

Preview of image 'wpgen-t5-im_morris_snakeshead-04.jpg'

Very neat!

Tried some simple procedural base textures (gradient + spiral2).

I'm still not quite sure what properties a good base texture
should have, some are quite impossible to line up (your *_03
sample also has some odd edges).

Post a reply to this message

Attachments:
Download 'wp_spiral2.jpg' (558 KB) Download 'wp_granite.jpg' (523 KB)

Preview of image 'wp_spiral2.jpg'

Preview of image 'wp_granite.jpg'

On 01/03/2012 04:44 PM, Jaime Vives Piqueres wrote:
> I finally found a simple way to create an endless stream of wallpapers
> for my virtual rooms, using the new tiling pattern type 5 (thanks,
> clipka!), combined with repeat warps in a texture_map.

BTW:

tiling pattern 1-24 = LeForgeron
tiling pattern 25-27 = clipka

Post a reply to this message

Thank you indeed, Jaime. Very nice and useful little job.

Is there a particular reason why the rendered tile is rectangular? Would 
it not make (more) sense if the tile was square?

Thomas

Post a reply to this message

Attachments:
Download 'jvp_tiling.png' (897 KB)

Preview of image 'jvp_tiling.png'

On 04/01/12 02:45, Christian Froeschlin wrote:
> Very neat!

   Thanks!

> Tried some simple procedural base textures (gradient + spiral2).

   Yeah... crackle is also a good base.

> I'm still not quite sure what properties a good base texture should
> have, some are quite impossible to line up (your *_03 sample also has
> some odd edges).

   Well, already repeating patterns are the best, of course. Also, you
can get ride of the random rotation, and use instead a fixed amount, to
line up the image patterns with the tiling pattern: it should give you
more chances to get a result without obvious seams.

   Another way I've just found, is to apply successive repeat warps
combined with 120 degree rotations, "a la stbenge":

#declare t_base=
texture{
     pigment{
       image_map{jpeg imagemap interpolate 2}
       rotate 90*x
       translate rand(r_pattern)*x
       translate rand(r_pattern)*z
       rotate 360*rand(r_pattern)*y
       scale im_scale
       #local nCount = 0;
       #while ( nCount < 360/120 )
         rotate 120*y
         warp { repeat .5*x flip x}
         warp { repeat sqrt(.75)*z flip z}
         #local nCount = nCount + 1;
       #end
     }
     finish{emission 1}
}

   This limits a bit the variety of the results, but you get ride of the
visible seams.

--
Jaime

Post a reply to this message

On 04/01/12 05:01, Jim Holsenback wrote:
> tiling pattern 1-24 = LeForgeron
> tiling pattern 25-27 = clipka

   Oops! Many thanks to LeForgeron then... sorry for the confusion. :(

--
Jaime

Post a reply to this message

On 04/01/12 10:33, Thomas de Groot wrote:
> Is there a particular reason why the rendered tile is rectangular?
> Would it not make (more) sense if the tile was square?

   As trial&error is my most usual approach to geometry, I first tried
square repeats, but it did not work. Then I noticed the tiling type five
is not square, so I then applied good & old Pythagoras to get the
correct ratio. I really don't know if it can be made square, or if it
makes more sense... I just assumed it should be that way for this
specific symmetry. And for my wallpapering usage, if it tiles
seamlessly, that's enough. But I guess you're already thinking on the
Gancaloon ceramic tiles... ;)

--
Jaime

Post a reply to this message

On 4-1-2012 11:28, Jaime Vives Piqueres wrote:
> On 04/01/12 10:33, Thomas de Groot wrote:
>> Is there a particular reason why the rendered tile is rectangular?
>> Would it not make (more) sense if the tile was square?
>
> As trial&error is my most usual approach to geometry, I first tried
> square repeats, but it did not work. Then I noticed the tiling type five
> is not square, so I then applied good & old Pythagoras to get the
> correct ratio. I really don't know if it can be made square, or if it
> makes more sense... I just assumed it should be that way for this
> specific symmetry. And for my wallpapering usage, if it tiles
> seamlessly, that's enough. But I guess you're already thinking on the
> Gancaloon ceramic tiles... ;)
>

That makes sense indeed. If the tiling type is not square, the image 
should not be either :-)  I missed that part indeed.

This macro makes a nice addition to your azulejos macro which I used 
(and shall use again) in Gancaloon. The possibilities are endless.

Thomas

Post a reply to this message

On 01/03/2012 04:44 PM, Jaime Vives Piqueres wrote:
> If you enjoy repetition, try the following code at your own risk... ;)
>
> --
> Jaime

Jamie,

Thanks for the #macro (sent my latest project in a different direction!) 
... easy to use, just scaling and orientation for my situation.

Jim

Post a reply to this message

Attachments:
Download 'work.png' (1221 KB)

Preview of image 'work.png'

On 12/01/12 17:02, Jim Holsenback wrote:
> Thanks for the #macro (sent my latest project in a different direction!)
> ... easy to use, just scaling and orientation for my situation.

   Very nice! ... but now it's asking for some wall lamps. :)

--
Jaime

Post a reply to this message