Hello,
    I'm having a couple of issues with blobs, and any input will be
welcome.  I apologize in advance if either of these has been addressed
elsewhere, but I haven't found anything.

    The first issue I'm having is that under certain circumstances, using
individually textured blob components causes a black image to be
created, when photons are enabled.  Here is a small scene which
demonstrates the problem:

#version 3.61;

#declare Use_Photons = yes;
#declare Use_Multi_Pos = yes;
#declare Use_Multi_Neg = yes;

#default { finish { ambient 0.1 diffuse 0.9 } }

#include "colors.inc"

global_settings {
    assumed_gamma 1.0
    max_trace_level 6
    #if(Use_Photons)
      photons {
        spacing 1/50
      }
    #end
}

camera {
    location <0, 4, -7>
    up y
    right x * image_width/image_height
    look_at y * 2
}

light_source {
    <20, 10, -30>, White
}

box {
    <-50, -1, -50>, <50, 50, 10>
    inverse
    texture {
      pigment { White }
    }
}

plane {
    y, 0
    texture {
      pigment {
        checker White, Black
        scale <2.5, 1, 2.5>
      }
    }
}

#declare Glass_F =
    finish {
      ambient 0
      specular 0.9
      roughness 0.001
      reflection {
        0, 1
        fresnel
      }
      conserve_energy
    }

#declare White_Glass =
    texture {
      pigment { White }
      finish { Glass_F }
    }

#declare Clear_Glass =
    texture {
      pigment { Clear }
      finish { Glass_F }
    }

blob {
    threshold 1

    sphere { <-1.5, 2, 0>, 3.696, 2 }

    sphere {
      <1.5, 2, 0>, 3.696, 2
      #if(Use_Multi_Pos)
        texture { White_Glass }
      #end
    }

    cylinder {
      <-1.5, 2, -10>, <-1.5, 2, 10>, 1, -3
      #if(Use_Multi_Neg)
        texture { White_Glass }
      #end
    }

    texture { Clear_Glass }

    interior {
      ior 1.62725
      fade_power 1001
      fade_distance 0.5
      fade_color White
    }

    photons {
      target
      reflection yes
      refraction yes
    }

}

The scene renders as expected unless photons are enabled and the second
(positive) component and third (negative) component are both
individually textured.  In this case the image is all black.  It seems
to render faster, though the statistics indicate that objects are still
being found.

In this example the solution would be easy as the negative component
doesn't really need to be textured.  However the actual scene I ran into
this with has the same problem with just a textured positive component.
   I've not been able to work out a more minimal example of this.

If anyone else has run into this, or sees something obvious I'm missing
I'd appreciate it.  I've attached some sample images of this scene. The
first is with photons off, and both textures enabled.  The rest have
photons enabled, and the positive component, the negative component, and
both components textured respectively.

I'll also mention I've tried this with POV-Ray 3.61 on Linux, as well as
with MegaPOV on Linux, and POV-Ray 3.61 on Windows with the same result.

I'll post my second issue in a separate thread.

-- 
-The Mildly Infamous Blue Herring

Post a reply to this message

Attachments:
Download 'blob issue 1 - no photons, neg and pos textures.png' (30 KB) Download 'blob issue 1 - photons, pos texture.png' (37 KB) Download 'blob issue 1 - photons, neg texture.png' (45 KB) Download 'blob issue 1 - photons, neg and pos texture.png' (1 KB)

Preview of image 'blob issue 1 - no photons, neg and pos textures.png'

Preview of image 'blob issue 1 - photons, pos texture.png'

Preview of image 'blob issue 1 - photons, neg texture.png'

Preview of image 'blob issue 1 - photons, neg and pos texture.png'