Wow, thats fantastic. Can I ask how the isosurface was defined ? i.e.
is it a sphere - this pattern ? Or am i way off base !

On Fri, 4 Jul 2008 21:06:51 +0100, "Tek" <tek### [at] evilsuperbraincom>
wrote:

>I was messing around with some multifractals and came up with this. It's 
>based on a crackle form <1,0,0> repeated like a perlin multi-fractal over 8 
>octaves. The heightfield renders pretty quick (19 minutes) but the isosurfae 
>took an amazing 9 hours!
>
>Here's the code for the pattern, the Curve value adjusts how the holes look. 
>Have a look at p.b.a to see what happens when I animate that value!:
>
>pigment {
> #local Curve=1/8; // small values make it look porous
> #local Omega=0.5;
> #local Lambda=2;
> #local Octaves=8;
> pigment_pattern {
>  average
>  pigment_map {
>   #local octave=0;
>   #while ( octave < Octaves )
>    [pow(Omega,octave)
>     pigment_pattern {
>      crackle form <.9,0,0>
>      scale pow(Lambda,-octave)
>      colour_map {[0 rgb 1][1 rgb 0]}
>     }
>     poly_wave 1/Curve
>    ]
>    #local octave=octave+1;
>   #end
>  }
> }
> poly_wave Curve
> colour_map {[0 rgb 1][1 rgb 0]}
>}

Post a reply to this message

"Rob Richards" <ari### [at] btinternetcom> wrote in message 
news:in4h74tllnc5r82ropj3sg006boujelu77@4ax.com...
> Wow, thats fantastic. Can I ask how the isosurface was defined ? i.e.
> is it a sphere - this pattern ? Or am i way off base !

You're exactly right, sphere - pattern.

-- 
Tek
http://evilsuperbrain.com

Post a reply to this message

"Tek" <tek### [at] evilsuperbraincom> wrote in message 
news:4878f316$1@news.povray.org...
> "Rob Richards" <ari### [at] btinternetcom> wrote in message 
> news:in4h74tllnc5r82ropj3sg006boujelu77@4ax.com...
>> Wow, thats fantastic. Can I ask how the isosurface was defined ? i.e.
>> is it a sphere - this pattern ? Or am i way off base !
>
> You're exactly right, sphere - pattern.
>
> -- 
> Tek
> http://evilsuperbrain.com
>
>

Hmmm, there must be something I'm doing really wrong then as all I can get 
out of this is a flat textured shape, I dont get any porous effects at all!

If I render it as a hightfield it also looks totally wrong :(

Meh, goes back to fiddle some more...

Cheers Dre

Post a reply to this message

"Dre" <and### [at] gmailcom> wrote:
> Hmmm, there must be something I'm doing really wrong then as all I can get
> out of this is a flat textured shape, I dont get any porous effects at all!
>
> If I render it as a hightfield it also looks totally wrong :(
>
> Meh, goes back to fiddle some more...
>
> Cheers Dre

I'm guessing that you're supposed to use it as an object pattern. Basically, an
object pattern is a pattern turned into an object that you can use in CSG.

-Mike

Post a reply to this message

"Tek" <tek### [at] evilsuperbraincom> wrote:
> I was messing around with some multifractals and came up with this. It's
> based on a crackle form <1,0,0> repeated like a perlin multi-fractal over 8
> octaves. The heightfield renders pretty quick (19 minutes) but the isosurfae
> took an amazing 9 hours!

It looks incredible! I'm wondering what the results would be in terms of
rendering times if you used a mesh instead of an isosurface. I know there's an
external utitlity to replace parametric objects with meshes. I can't recall if
there's also one for isosurfaces.

Of course, the typical parametric curve tends to be much smoother than the
object you've created here. Not sure if this is the ideal application for
meshes.

-Mike

Post a reply to this message

"SharkD" <nomail@nomail> wrote in message 
news:web.487abb1b1771580b302c26d00@news.povray.org...
> "Dre" <and### [at] gmailcom> wrote:
>> Hmmm, there must be something I'm doing really wrong then as all I can 
>> get
>> out of this is a flat textured shape, I dont get any porous effects at 
>> all!
>>
>> If I render it as a hightfield it also looks totally wrong :(
>>
>> Meh, goes back to fiddle some more...
>>
>> Cheers Dre
>
> I'm guessing that you're supposed to use it as an object pattern. 
> Basically, an
> object pattern is a pattern turned into an object that you can use in CSG.
>
> -Mike
>

hmm, still above my abilities, I'll keep reading...

Thanks for the info though.

Cheers Dre

Post a reply to this message

"Dre" <and### [at] gmailcom> wrote:
> "SharkD" <nomail@nomail> wrote in message
> > I'm guessing that you're supposed to use it as an object pattern.
> > Basically, an
> > object pattern is a pattern turned into an object that you can use in CSG.
> >
> > -Mike
> >
>
> hmm, still above my abilities, I'll keep reading...
>
> Thanks for the info though.
>
> Cheers Dre

Doh! I got that completely backwards! An object pattern is an *object* that is
turned into a *pattern*, not the other way around. Sorry!

-Mike

Post a reply to this message

Wasn't it Dre who wrote:
>"Tek" <tek### [at] evilsuperbraincom> wrote in message
>news:4878f316$1@news.povray.org...
>> "Rob Richards" <ari### [at] btinternetcom> wrote in message
>> news:in4h74tllnc5r82ropj3sg006boujelu77@4ax.com...
>>> Wow, thats fantastic. Can I ask how the isosurface was defined ? i.e.
>>> is it a sphere - this pattern ? Or am i way off base !
>>
>> You're exactly right, sphere - pattern.
>>
>> --
>> Tek
>> http://evilsuperbrain.com
>>
>>
>
>Hmmm, there must be something I'm doing really wrong then as all I can get
>out of this is a flat textured shape, I dont get any porous effects at all!
>
>If I render it as a hightfield it also looks totally wrong :(
>
>Meh, goes back to fiddle some more...

It goes something like this:

#version 3.6;

global_settings {assumed_gamma 1.0}

camera {location  <0,0,-10> look_at <0,0,0>}

background {rgb <.8,.8,1>}

light_source {<-30, 100, -30> color rgb 0.5}
light_source {<0, 10, -30> color rgb 0.5}

#declare P = function{pigment {
 #local Curve=1/8; // small values make it look porous
 #local Omega=0.5;
 #local Lambda=2;
 #local Octaves=8;
 pigment_pattern {
  average
  pigment_map {
   #local octave=0;
   #while ( octave < Octaves )
    [pow(Omega,octave)
     pigment_pattern {
      crackle form <.9,0,0>
      scale pow(Lambda,-octave)
      colour_map {[0 rgb 1][1 rgb 0]}
     }
     poly_wave 1/Curve
    ]
    #local octave=octave+1;
   #end
  }
 }
 poly_wave Curve
 colour_map {[0 rgb 1][1 rgb 0]}
}}

#declare  S = function {x*x + y*y + z*z - 1}

isosurface {
  function { S(x,y,z) - P(x,z,y).grey*2 }
        max_gradient 70
        contained_by{sphere{0,1.5}}
        pigment {rgb 1}
  scale 3
}

I've not done any radiosity or other fancy rendering on this, so it
renders a bit faster but doesn't look as good.

Try tweaking the numbers in "grey*2" and "scale 3".

-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message

"Mike Williams" <nos### [at] econymdemoncouk> wrote in message 
news:+9fE### [at] econymdemoncouk...
> Wasn't it Dre who wrote:
>>"Tek" <tek### [at] evilsuperbraincom> wrote in message
>>news:4878f316$1@news.povray.org...
>>> "Rob Richards" <ari### [at] btinternetcom> wrote in message
>>> news:in4h74tllnc5r82ropj3sg006boujelu77@4ax.com...
>>>> Wow, thats fantastic. Can I ask how the isosurface was defined ? i.e.
>>>> is it a sphere - this pattern ? Or am i way off base !
>>>
>>> You're exactly right, sphere - pattern.
>>>
>>> --
>>> Tek
>>> http://evilsuperbrain.com
>>>
>>>
>>
>>Hmmm, there must be something I'm doing really wrong then as all I can get
>>out of this is a flat textured shape, I dont get any porous effects at 
>>all!
>>
>>If I render it as a hightfield it also looks totally wrong :(
>>
>>Meh, goes back to fiddle some more...
>
> It goes something like this:
>
> #version 3.6;
>
> global_settings {assumed_gamma 1.0}
>
> camera {location  <0,0,-10> look_at <0,0,0>}
>
> background {rgb <.8,.8,1>}
>
> light_source {<-30, 100, -30> color rgb 0.5}
> light_source {<0, 10, -30> color rgb 0.5}
>
> #declare P = function{pigment {
> #local Curve=1/8; // small values make it look porous
> #local Omega=0.5;
> #local Lambda=2;
> #local Octaves=8;
> pigment_pattern {
>  average
>  pigment_map {
>   #local octave=0;
>   #while ( octave < Octaves )
>    [pow(Omega,octave)
>     pigment_pattern {
>      crackle form <.9,0,0>
>      scale pow(Lambda,-octave)
>      colour_map {[0 rgb 1][1 rgb 0]}
>     }
>     poly_wave 1/Curve
>    ]
>    #local octave=octave+1;
>   #end
>  }
> }
> poly_wave Curve
> colour_map {[0 rgb 1][1 rgb 0]}
> }}
>
> #declare  S = function {x*x + y*y + z*z - 1}
>
> isosurface {
>  function { S(x,y,z) - P(x,z,y).grey*2 }
>        max_gradient 70
>        contained_by{sphere{0,1.5}}
>        pigment {rgb 1}
>  scale 3
> }
>
> I've not done any radiosity or other fancy rendering on this, so it
> renders a bit faster but doesn't look as good.
>
> Try tweaking the numbers in "grey*2" and "scale 3".
>
> -- 
> Mike Williams
> Gentleman of Leisure

Whoa, okay so I was waaaaaaay off base here!

But I now know where I went wrong (massivly wrong, hehehe).  I'm still 
learning how to use isosurfaces properly and that was my mistake, thanks 
very much for that bit of code, thats cleared that up for me nicely.

Now to start playing around!

Cheers Dre

Post a reply to this message

"SharkD" <nomail@nomail> wrote in message 
news:web.487addc91771580b302c26d00@news.povray.org...
> "Dre" <and### [at] gmailcom> wrote:
>> "SharkD" <nomail@nomail> wrote in message
>> > I'm guessing that you're supposed to use it as an object pattern.
>> > Basically, an
>> > object pattern is a pattern turned into an object that you can use in 
>> > CSG.
>> >
>> > -Mike
>> >
>>
>> hmm, still above my abilities, I'll keep reading...
>>
>> Thanks for the info though.
>>
>> Cheers Dre
>
> Doh! I got that completely backwards! An object pattern is an *object* 
> that is
> turned into a *pattern*, not the other way around. Sorry!
>
> -Mike
>

Thats ok I was way off anyway, its been cleared up now though so all good!

Cheers Dre

Post a reply to this message