Recent discussions about povray rendering quality inspired me to do 
this.  I was actually more interested in quality anti-aliasing, as I've 
had some pretty bad AA before of edges against very bright background 
surfaces in radiosity settings.  So, it's the first time I've used such 
impressive AA.  It took 4 hours (radiosity per se was pretty fast) but 
is well worth it.

code:


#local HQ = 1;
#local GI = 1;
#local GIgather = 0;
#local CAUSTICS = 0;
#local CAUSTICSgather = 1;

#default { finish { ambient 0 diffuse .6 } }

global_settings {
     max_trace_level 12
     adc_bailout .01
     #if (GI)
     radiosity {
         brightness 1.8
         gray_threshold .7
         #if (GIgather)
         save_file "rsocp.rad"
         #else
         load_file "rsocp.rad"
         #end
         always_sample off

         count 40*3
         error_bound .4
         low_error_factor .8
         pretrace_end .006
         nearest_count 8
     }
     #end

     #if (CAUSTICS)
     photons { count 40000
         #if (CAUSTICSgather)
         save_file "rsocp.phm"
         #else
         load_file "rsocp.phm"
         #end
     }
     #end
}

union {
     sphere { 0, 1
         pigment { rgb 1 }
         finish { ambient .8 diffuse .8 }
         scale 1000
     }

     sphere { 0, 1
         pigment { rgbt <1,1,1,0> }
         finish { ambient .01 diffuse .3 brilliance 1
             specular 1 roughness .001
             conserve_energy
             reflection { .2,.5 fresnel exponent 1 falloff 2 }
         }
     }
     plane { y, -1
         pigment { checker rgb 1 rgb 0 }
     }

     difference {
         box { -8,8 }
         plane { -z, -7 pigment { rgbt 1 } }
         pigment { rgb .6 }
         translate z*1
     }

     light_source { z*20 .7 fade_power 2 fade_distance 18 rotate -x*30 
rotate y*20
         #if (HQ) area_light x*2,y*2,5,5 orient circular adaptive 0 
jitter #end
     }

     rotate y*40
     rotate -x*10
     translate z*5.3
}

#if (!GI)
light_source { -8*z .6 shadowless }
#end

camera { angle 60
     //#if (HQ) aperture .01 blur_samples 32*64 confidence .999 variance 
0 #end
     #if (HQ) aperture .01 blur_samples 32*16 confidence .98 variance 0 #end
}

Post a reply to this message

Attachments:
Download 'biased_rsocp.jpg' (37 KB)

Preview of image 'biased_rsocp.jpg'

A 10 minutes rendering with brute force and 1 core.

temptation was too strong...

Post a reply to this message

Attachments:
Download 'test_2.jpg' (265 KB)

Preview of image 'test_2.jpg'

fidos wrote:
> A 10 minutes rendering with brute force and 1 core.

it's amazing.  Despite the noise, antialising is quite good.  Comment 
out the camera aperture settings in the scene for normal povray and the 
plane becomes a horrid mess of pixels...

> temptation was too strong...

I was expecting you to give it a shot! :)

keep it up, you know I like these challenges... :)

next I'm dropping the light_source and try to get this same diffuse 
sphere shadow on the ground.

Post a reply to this message

and here it is, no light_sources and a few extra tweakings, like recursion_limit
2 to more closely resemble the path tracing.  BTW, I was in a hurry and got the
title wrong, but fidos was kind enough not to let it die in vain...

#local HQ = 1;
#local GI = 1;
#local GIgather = 0;
#local CAUSTICS = 0;
#local CAUSTICSgather = 1;

#default { finish { ambient 0 diffuse .56 } }

global_settings {
    max_trace_level 12
    adc_bailout .01
    #if (GI)
    radiosity {
        brightness 2.5
        gray_threshold .7
        #if (GIgather)
        save_file "rsocp.rad"
        #else
        load_file "rsocp.rad"
        #end
        always_sample off

        count 80*6
        error_bound .4
        low_error_factor .8
        pretrace_end .006
        nearest_count 12
  recursion_limit 2
    }
    #end

    #if (CAUSTICS)
    photons { count 40000
        #if (CAUSTICSgather)
        save_file "rsocp.phm"
        #else
        load_file "rsocp.phm"
        #end
    }
    #end
}

union {
 // sky
    sphere { 0, 1
        pigment { rgb 1 }
        finish { ambient 1.6 diffuse .8 }
        scale 1000
    }

    sphere { 0, 1
        pigment { rgbt <1,1,1,0>/2 }
        finish { ambient 0 diffuse .3 brilliance 1.1
            specular 1 roughness .003
            conserve_energy
            #if (!GIgather) reflection { .06,.5 fresnel exponent 1 falloff 2 }
#end
        }
  interior { ior 2 } // forgot the ior for fresnel reflection!!
  hollow
    }
    plane { y, -1
        pigment { checker rgb 1 rgb 0 }
    }

    difference {
        box { -8,8 }
        plane { -z, -7 pigment { rgbt 1 } }
        pigment { rgb .6 }
        translate z*1
    }

 #if (0)
    light_source { z*20 .7 fade_power 2 fade_distance 18 rotate -x*30 rotate
y*20
        #if (HQ) area_light x*2,y*2,5,5 orient circular adaptive 0 jitter #end
    }
 #end

    rotate y*40
    rotate -x*10
    translate z*5.3
}

#if (!GI)
light_source { -8*z .6 shadowless }
#end

camera { angle 60
    //#if (HQ) aperture .01 blur_samples 32*64 confidence .999 variance 0 #end
    //#if (!GIgather & HQ) aperture .01 blur_samples 32*16 confidence .98
variance 0 #end
    #if (!GIgather & HQ) aperture .008 blur_samples 32*10 confidence .96
variance 0 #end
}

Post a reply to this message

Attachments:
Download 'biased_rsocp-wip3.png' (119 KB)

Preview of image 'biased_rsocp-wip3.png'

oh, rendertime of 2:04 hours on a P4 2.66, thanks to the high-quality AA from
camera aperture settings...

Post a reply to this message

BTW, why is it that the ground just in front of the big open box and 
beyond is slightly darker?

Post a reply to this message

nemesis wrote:
> BTW, why is it that the ground just in front of the big open box and
> beyond is slightly darker?

Looks like a bug. They should definitely be white. And there should not
be a rapid change in lightness where the box "ends".

Post a reply to this message