|
 |
Eric CHAPUZOT wrote:
> very nice... but generaly, that 's the other side of plug which is
> useful...
Eh?
Je suis desolee, mais peut etre je ne comprends pas le rigole ici :-)
J'ai model'ee le fiche completement, avec tout les details interieur. Si je
faites une "zoom" au fiche "N" on peut voir tout les details :-)
I am veryy sorry, but I do not get the joke. The connectors are installed on
the splitter and the antennas, it just waits for the cables - which I have
problems with.
The connectors are fully modelled, i.e. with all the internal details. I can
zoom in and you can see the small parts on the inside... if you want to :-)
Regards,
Ekki
Post a reply to this message
|
|
|
|
Ekki Plicht wrote:
> As illustration to a discussion in povray.newusers (Laying cables)
Ekki, I'm guessing that Rune's Inverse Kinematics might help you:
http://runevision.com/show.asp?id=97
You specify a start point, an end point and the vectors at each of those
points. Here's an example scene
__SCENE__
// INVERSE KINEMATICS CABLE INCLUDE FILE: SAMPLE FILE
// ***************************************************
// This scene shows how to make a cable using Rune's
// Inverse Kinematics Include file.
#include "colors.inc"
global_settings {
assumed_gamma 1.0
}
// ----------------------------------------
#declare yCam = camera {
location <2.0, 14, -4>
direction 1.5*z
right x*image_width/image_height
look_at <2.0, 0.0, 2.0>
}
#declare zCam = camera {
location <0.0, 3, -14>
direction 1.5*z
right x*image_width/image_height
look_at <0.0, 0.0, 0.0>
}
#declare xCam = camera {
location <-14, 3, 0>
direction 1.5*z
right x*image_width/image_height
look_at <0.0, 0.0, 0.0>
}
sky_sphere {
pigment {
gradient y
color_map {
[0.0 rgb <0.6,0.7,1.0>]
[0.7 rgb <0.0,0.1,0.8>]
}
}
}
light_source {
<0, 0, 0> // light's position (translated below)
color rgb <1, 1, 1> // light's color
translate <-30, 30, -30>
}
// ----------------------------------------
plane {
y, -2
pigment { color rgb <0.7,0.5,0.3> }
}
// CABLE PARAMETERS
#declare ikn_p1 = 0; // Startpoint of cable
#declare ikn_z1 = y; // Forward vector at startpoint
#declare ikn_y1 = z; // Up vector at startpoint
#declare ikn_p2 = <4,3,3>; // Endpoint of cable
#declare ikn_z2 = x; // Forward vector at endpoint
#declare ikn_y2 = y; // Up vector at endpoint
#declare ikn_twist = 0; // Attempted twisting.
#declare ikn_radius1 = 0.2; // Radius at startpoint
#declare ikn_radius2 = 0.2; // Radius at endpoint
#declare ikn_length = 8; // Length of cable
#declare ikn_links = 400; // Number of links in cable
// TEXTURE FOR THE CABLE:
#declare CableTexture =
texture {
pigment { Yellow }
finish {phong 1}
}
// STIFFNESS VALUES FOR CABLE:
#declare ikn_stiffness1 = 2; // Relative stiffnes at startpoint
#declare ikn_stiffness2 = 1; // Relative stiffnes at endpoint
// INCLUDE IKN.INC:
#include "ikn.inc"
// CREATE CABLE:
#declare Cable =
union {
#declare C = 0; // Start at link 0...
#while (C<=ikn_links-1) // ...and run through all links.
#declare T = C/(ikn_links-1); // Goes from 0 to 1 along the cable.
sphere { // Make a sphere...
0, 1
texture {
CableTexture
// Translate the texture this way for UV texturing:
// (that formula work well for most cables)
translate -z*T*ikn_length/(ikn_radius1/2+ikn_radius2/2)
}
scale ikn_r[C] // ...and scale it...
transform ikn_transform[C] // ...and transform it
automatically.
}
#declare C = C+1;
#end
}
// Some simple plugs:
cylinder {
<0,-1,0>
<0,0,0>
0.4
pigment { Grey }
}
cylinder {
<4,3,3>
<5,3,3>
0.4
pigment { Grey }
}
object {Cable}
// Try all three cams -- as per sample image
camera{ yCam }
Post a reply to this message
Attachments:
Download 'cables.jpg' (51 KB)
Preview of image 'cables.jpg'
|
|
|
|
Rick Measham wrote:
> Ekki Plicht wrote:
>> As illustration to a discussion in povray.newusers (Laying cables)
>
> Ekki, I'm guessing that Rune's Inverse Kinematics might help you:
> http://runevision.com/show.asp?id=97
>
> You specify a start point, an end point and the vectors at each of those
> points. Here's an example scene
[...]
Excellent! Many thanks, that looks exactly like what I was looking for.
Unfortunately my other hobby takes over for this weekend, so I cannot try it
out until next week... I will come back with result.
Again thanks.
Ekki
Post a reply to this message
|
|
