Ever seen one of those anniversary clocks under a glass dome with the little
spinning weights?  This little animation gives an alternative, Rube Goldburg
style, pendulum.  I haven't worked out the escapment and gearing yet, but
they shouldn't take long.  You can change the union to merge and add
transparency, but you'll pay a high price in render time.

// Persistence of Vision Ray Tracer Scene Description File
// File: Slither
// Vers: 3.5
// Desc: Snail Spring?
// Date: 04/14/2004
// Auth: Lonnie Welch
//

#version 3.5;

#include "colors.inc"
#include "shapes.inc"

global_settings {
  assumed_gamma 1.0
}

#declare myclock=clock;

// ----------------------------------------

camera {
  location  <-2.0, 4.5, -24.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <5.0, 6.0,  0.0>
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source {
  <-20, 30, -40>
  color rgb <1, 1, 1>
}

plane {
  y, -1
  pigment { color rgb <0.7,0.5,0.3> }
}

// -------------------------------------------------

#macro snail (mx,my,mz,heading,elevation,length)
  #local scount=1;
  union{
    #while (scount<186 & length>.1)
      #declare ny=sin(elevation*pi/180)*length+my;
      #declare nl=cos(elevation*pi/180)*length;
      #declare nx=cos(heading*pi/180)*nl+mx;
      #declare nz=sin(heading*pi/180)*nl+mz;
      object {Connect_Spheres(<mx,my,mz>, length/3,
        <nx,ny,nz>, length/3*.98) pigment {color rgb <.7,.8,.5>}}
      sphere {<nx,ny,nz>,length/3*.98 pigment {color rgb <.7,.8,.5>}}
      #declare mx=nx;
      #declare my=ny;
      #declare mz=nz;
      #declare heading=heading+sin(myclock*pi*2)*10;
      #declare elevation=elevation-24;
      #declare length=length*.98;
      #declare scount=scount+1;
    #end
  }
#end

#declare mx=0;
#declare my=2;
#declare mz=0;
#declare heading=0;
#declare elevation=110;
#declare length=3;

#declare mysnail=snail (mx,my,mz,heading,elevation,length)

object {mysnail}

//--------------------------------------------------------
/*
// Here is the .ini file for the animation

Antialias=Off

Antialias_Threshold=0.2
Antialias_Depth=3

Input_File_Name=slither.pov

Initial_Frame=1
Final_Frame=300
Initial_Clock=0
Final_Clock=1

Cyclic_Animation=on
Pause_when_Done=off


*/


---
Outgoing mail is certified Virus Free.
Checked by AVG anti-virus system (http://www.grisoft.com).
Version: 6.0.590 / Virus Database: 373 - Release Date: 2/16/2004

Post a reply to this message

Attachments:
Download 'slith.png' (56 KB)

Preview of image 'slith.png'