|
 |
Urs Holzer wrote:
> Dan P wrote:
>
>
>>Neat! It looks like the transmit value might be a bit high -- what happens
>>if you set transmit to 0?
>
>
> I don't understand you. Changing the transmit value of the pigment of the
> spheres wouldn't make any sense because you would only see white balls.
> This is the only transmit in this scene. All other transmit values should
> be 0.
I need to see the code to understand what you mean. The marbles looked
like you had a transmit value to them because of the unnatural look
inside. But, I could be totally off my rocker on this (making this just
another one of the billions of things I'm off my rocker on) so without
the code, I'm just making wild guesses. :-)
--
Respectfully,
Dan P
http://<broken link>
Post a reply to this message
|
|
|
|
Dan P wrote:
> I need to see the code to understand what you mean. The marbles looked
> like you had a transmit value to them because of the unnatural look
> inside. But, I could be totally off my rocker on this (making this just
> another one of the billions of things I'm off my rocker on) so without
> the code, I'm just making wild guesses. :-)
A ball looks like this:
sphere {
0, 0.5
pigment { rgbt 1 }
finish { phong 0.8 }
hollow
interior {
ior 1.5
media {
scattering { 1, rgb 1 extinction 1 }
density {
crackle
scale 0.1
}
}
}
}
Post a reply to this message
|
|
|
|
Urs Holzer wrote:
> Dan P wrote:
>
>
>>I need to see the code to understand what you mean. The marbles looked
>>like you had a transmit value to them because of the unnatural look
>>inside. But, I could be totally off my rocker on this (making this just
>>another one of the billions of things I'm off my rocker on) so without
>>the code, I'm just making wild guesses. :-)
>
>
> A ball looks like this:
>
> sphere {
> 0, 0.5
> pigment { rgbt 1 }
> finish { phong 0.8 }
> hollow
> interior {
> ior 1.5
> media {
> scattering { 1, rgb 1 extinction 1 }
> density {
> crackle
> scale 0.1
> }
> }
> }
> }
I played around with it a bit and came up with this scene for fun:
#include "colors.inc"
// radiosity (global illumination) settings
global_settings {
radiosity {
pretrace_start 0.08 // start pretrace at this size
pretrace_end 0.04 // end pretrace at this size
count 35 // higher -> higher quality (1..1600)
[35]
nearest_count 5 // higher -> higher quality (1..10) [5]
error_bound 1.8 // higher -> smoother, less accurate
[1.8]
recursion_limit 3 // how much interreflections are
calculated (1..5+) [3]
low_error_factor .5 // reduce error_bound during last
pretrace step
gray_threshold 0.0 // increase for weakening colors
(0..1) [0]
minimum_reuse 0.015 // reuse of old radiosity samples [0.015]
brightness 1 // brightness of radiosity effects
(0..1) [1]
adc_bailout 0.01/2
//normal on // take surface normals into account
[off]
//media on // take media into account [off]
//save_file "file_name" // save radiosity data
//load_file "file_name" // load saved radiosity data
//always_sample off // turn sampling in final trace off [on]
//max_sample 1.0 // maximum brightness of samples
}
}
camera
{
location <0, 0.7, -2>
look_at <0, 0, 0>
up y
right image_width / image_height * x
}
background
{
rgb 0
}
sphere
{
0, 0.5
hollow
pigment { rgbft <1, 1, 1, 1, 0> }
finish
{
//phong 0.8
specular 0.8 // New syntax is "specular"
reflection 0.1
conserve_energy // Often helps, but does not affect this image.
}
interior
{
ior 1.5
media
{
absorption 0.1
scattering
{
1, rgb 1
extinction 1
}
density
{
crackle
scale 0.1
color_map
{
[0 rgb 0 ]
[1 rgb <0.4, 0.6, 0.9>*-1*10 ]
}
}
}
}
}
plane
{
y, -0.5
pigment
{
checker rgb 0 rgb 2
scale <0.3, 0.3, 0.3>
rotate 30*y
}
finish
{
ambient 1
reflection 0.6
specular 1
}
}
sphere
{
0, 6
hollow
pigment
{
color rgbft <1, 1, 1, 1, 0>
}
finish
{
ambient 0
reflection 0
specular 0
}
interior
{
media
{
emission rgb 1
absorption 1
scattering
{
3, 1
}
density
{
wrinkles
scale <1, 0.1, 1>
}
}
}
}
--
Respectfully,
Dan P
http://<broken link>
Post a reply to this message
Attachments:
Download 'test.jpg' (80 KB)
Preview of image 'test.jpg'
|
|
org> wrote in message
news: