As Raf256 has already said, please don't post bmp files like this one
because a space- and time-saving jpeg is best. You should consider
cancelling your original message for the sake of others with slow
connections.

As to the problem... it looks like the media sampling is way too low.

I've redone your scene (not perfect, maybe, but better) as shown below, and
I have the light source much dimmer and the mirror reflecting at a more
typical amount. I think that pink artifact could have been a result of the
extreme reflection, bright light and low sampling. Any one or a combination
of those.

Expect a much slower rendering with more samples, but also don't lower
photon count too much or raise spacing too high. The settings I used seem
okay, but the spot on the grey block gets messed up when samples are lower
so you might encounter that anomaly if you go about changing things while
checking on it. I believe the starting point of the light is sharper because
a cylindrical spotlight is really just constrained to a cylinder shape,
parallel or not. And I think that in the past it's been said this isn't a
good light for media and photons in the first place. However I don't have
any info at the moment to back that up.

Image attached as well.

#include "colors.inc"

global_settings {
  max_trace_level 4
  photons {
   // spacing 0.03
    count 5000
   // autostop 0
    media 100,2
    jitter 0.3
    }

}

camera
{
   location <0,8,18>
   look_at <0,0,8>
}

light_source
{
   <0,10,10>
   color <.5,.5,.5>
   media_interaction off
   photons { reflection off refraction off }
}


// laser
light_source{
  <-2,1,9>, colour rgb<0,3,0>
  cylinder
  radius .2
  falloff .21
  tightness .1 // a little softness
  parallel
  point_at <0,1,14>
  media_interaction on
   photons { reflection on refraction off }
  }


box
{
   <-1,0,16>,
   <1,2,14>
   pigment { rgb<0,0,0> }
   finish
   {

      ambient 0
      diffuse 0
      reflection 1//0
   }
   photons
   {
      target
      reflection on
      refraction off
      collect off
   }
}


box
{
   <-4,-2,7>,
   <4,2,6>
   pigment { Grey }
}


box{<50,50,50> <-50,0.0001,-50>
  hollow
  pigment{checker rgb<0.1,0.1,0.1> rgb<0.9,0.9,0.9>}
  interior{
    media{
      method 3
      intervals 3
      samples 60,60 // perhaps the most important factor
      jitter 0
      scattering{4, 0.3
 extinction 0 // 0 enhances light beam while keeping scene visible
      }
      }
    }
  }

Post a reply to this message

Attachments:
Download 'laserremaketest.jpg' (23 KB)

Preview of image 'laserremaketest.jpg'