|
 |
I tried to dl the file JRG, but it seems to be corrupted toward the end.
I shall try again, but twice it gave me the same error..
JRG <jrg### [at] hotmail com> wrote:
> Hi Tony,
> couldn't find the very original file, but have readapted the glass-version
> scene *on the fly*. They look quite the same.
> Cheers,
> --
> Jonathantwentyyearsold.
> "Tony[B]" <ben### [at] catholicorg> ha scritto nel messaggio
> news:3bbcbc3c@news.povray.org...
>> Needs higher precision... it looks kinda worn down.
>>
>>
>> PS: I would like source or a 1280xH rendering. :)
>>
>>
Post a reply to this message
|
|
|
|
The file is okay (since I could dled it without problems).
But why bother? ;) :
// Persistence Of Vision Ray Tracer Scene Description File
// File: isofortony.pov
// Vers: 3.5
// Desc: Povray 3.5 demonstration scene
// Date: 4 October 2001
// Auth: Jonathan Rafael Ghiglia - isosurface equation by Warp
//
// SWITCHES
#declare AREA_LIGHT=on;
#declare PHOTONS=on;
global_settings {
max_trace_level 15
#if (PHOTONS) photons {count 1000000 autostop 0} #end
}
camera {
location <-2,3,-3>
//right x
look_at 0
}
light_source {
<4,5,-5>
rgb <1,1,.98>*2.5
//rgb <.98,1,1>*2.5
fade_distance 5
fade_power 2
#if (AREA_LIGHT) area_light x,y,6,6 adaptive 0 jitter circular
orient #end
}
light_source {
<0,3.5,5>
rgb <1,.9,.6>*0.6
//rgb <.6,.9,1>*0.6
fade_distance 5
fade_power 3
#if (AREA_LIGHT) area_light x,y,5,5 adaptive 0 jitter circular
orient #end
}
sky_sphere { pigment {rgb <.7,.85,1>*0.5}}
plane {
y,0
pigment { rgb 1 }
finish {
ambient 0
diffuse 0.5
specular .4
roughness .01
reflection .1 }
}
#include "functions.inc"
#declare BUMP = function {pigment {crackle color_map {[0 rgb 0][1 rgb 1]}
turbulence 0.5 cubic_wave}}
#declare TORUS = function
{sqrt((sqrt(x^2+z^2)-1.5)^2+y^2)-(.3+.2*sin(8*atan2(x,z)))}
isosurface {
function { TORUS(x,y,z)-BUMP(1.5*x,1.5*y,1.5*z).red*0.19}
contained_by { box { -<2,.5,2>,<2,.7,2> } }
max_gradient 6.272
//evaluate 1,10,0.99
accuracy 10^-3
translate .5*y
scale .7
pigment {rgb <1,.6,.2>*0.7}
finish {
ambient 0
diffuse 0.1
specular 3
roughness 0.04
reflection {0.5 metallic}
metallic
brilliance 1.5}
#if (PHOTONS) photons {target reflection on refraction off collect
off} #end
}
Post a reply to this message
|
|
|
|
dankeschane![1]
for those that don't know, it means thank you
Gary
[1]apolagies to the German if I spelled it wrong.
JRG <jrg### [at] hotmailcom> wrote in message news:3bbcc1c4@news.povray.org...
> Hi Tony,
> couldn't find the very original file, but have readapted the glass-version
> scene *on the fly*. They look quite the same.
>
> Cheers,
> --
> Jonathantwentyyearsold.
>
>
> "Tony[B]" <ben### [at] catholicorg> ha scritto nel messaggio
> news:3bbcbc3c@news.povray.org...
> > Needs higher precision... it looks kinda worn down.
> >
> >
> > PS: I would like source or a 1280xH rendering. :)
> >
> >
>
>
>
Post a reply to this message
|
|
