|
 |
Very artistic, funny, new!
Love it where the virus goes through the plane, how did you do that? is the
plane really a height_field?
-Peter
> <voice class="panic">
> ARGHHHH!! HELP!!
>
> The PoV-Ray Proximity Viruses are escaping from the Vault beneath the
> Infinite Checkered Plain!! Can anything save the venerable Chrome
> Sphere, stalked by such a menace?!? All is lost ... all is looossst ...
> </voice>
>
> Mike Andrews
Post a reply to this message
|
|
|
|
Hi Peter,
Peter Hertel wrote:
>
> Very artistic, funny, new!
Thanks :-)
> Love it where the virus goes through the plane, how did you do that? is the
> plane really a height_field?
>
An interstection of unions of plane and heightfield ... well, here's the
code for the plain. I'll post the source for the image if there's
interest.
Bye for now,
Mike Andrews.
#declare Plane = union {
plane{ y, 0 }
height_field {
function 200,200 {
pigment {
cylindrical poly_wave 3 rotate 90*x translate 1 scale 0.5
}
}
translate -<0.5,0,0.5>
scale <40,10,40>
}
}
difference {
object { Plane }
object { Plane translate -y }
height_field {
function 400,400 {
pigment {
cylindrical poly_wave 3
pigment_map {
[0.1 rgb 0]
[0.5 radial frequency 7 colour_map {[0 rgb 1][0.1 rgb 0][0.9
rgb 0][1 rgb 1] } ]
[1 rgb 1]
}
scale 5
warp { turbulence 0.5 }
scale 1/5
rotate 90*x translate 1 scale 0.5
}
}
translate -<0.5,0,0.5>
scale -<60,10,60>
translate 10*y
}
scale 2
#declare pigPov = pigment { object { text{ttf"povlogo""P"9 0} colour
rgb 0, rgb 1 } translate -3*z rotate 90*x }
pigment{
pigment_pattern {
pigPov
translate x
warp {repeat 2*x}
warp {repeat sin(radians(60))*2*z offset x}
warp {repeat y}
scale 2
}
pigment_map {
[0.5
pigment_pattern { checker rgb 0, rgb 1 translate -0.5 scale
<7,100,7> }
pigment_map {
[0.5 cylindrical scale 20 colour_map {[0 rgb 0][0.5 rgb
<.9,.9,1> ][1 rgb 0.7]} ]
[0.5 cylindrical scale 20 colour_map {[0 rgb 1][0.5 rgb
<.8,.8,.9>][1 rgb 0.7]} ]
}
]
[0.5
pigment_pattern { checker rgb 0, rgb 1 translate -0.5 scale
<7,100,7> }
pigment_map {
[0.5 cylindrical scale 20 colour_map {[0 rgb 0][0.45 rgb
x][0.9 rgb 0.7]} ]
[0.5 cylindrical scale 20 colour_map {[0 rgb 1][0.45 rgb
x][0.9 rgb 0.7]} ]
}
]
}
translate <5,0,20>-<-20,0,80>
warp { black_hole <5,0,20>-<-20,0,80>, 20 strength 2 falloff 4 }
}
finish{diffuse 1 ambient 0}
translate -6*y
translate <-20,0,80>
}
Post a reply to this message
|
|
ac