POV-Ray : Newsgroups : povray.binaries.images : Light & Shadows : Re: Light & Shadows Server Time: 26 Feb 2021 21:32:19 GMT
  Re: Light & Shadows  
From: Norbert Kern
Date: 23 Apr 2020 17:45:01
Cousin Ricky <ric### [at] yahoocom> wrote:

> > Beside this philosophical reasons it was important for me in a more technical
> > sense as it is the first image since 15 years developed with assumed_gamma 1.
> > I think, I'll stay at this since it is obviously possible to realize strong
> > contrasts with assumed_gamma 1...
>
> I would expect so.  Real life does it linearly; it is our perceptions
> that are non-linear.  My response to a low contrast scene has not been
> to fiddle with the assumed gamma, but to change the lighting environment.


In fact texturing was really simple. A finish like "specular 0.3 roughness 0.003
diffuse 0.6 ambient 0" worked with nearly all objects. When I used assumed_gamma
2.2 there was much more work to do :-)

The biggest change was to reduce the radiosity contribution of the sky.
Here I used rather extreme settings (at least for me) -

#version 3.7;

#declare RAD = 8;

global_settings {
        assumed_gamma 1
        max_trace_level 255
        noise_generator 2
                radiosity {
                        pretrace_start 0.08
                        pretrace_end   0.04/RAD
                        count 30*RAD
                        nearest_count min (20, RAD)
                        error_bound 3/RAD
                        low_error_factor 0.5
                        recursion_limit 1
                        gray_threshold 0
                        minimum_reuse 0.015
                        brightness 1
                        adc_bailout 0.005
                        normal on
                        media off
                }
}

#declare skyf = 0.5;

light_source {
        <0,0,40000> color srgb (<2.42,2.23,1.87>+2.173*0.3)*0.85
        area_light <1000,0,0>, <0,1000,0> 5,5 adaptive 0 jitter circular orient
        rotate <-47,-50,0>
}

sky_sphere {
        pigment {
                function {max (min (y, 1), 0)}
                color_map {
                        [0.0000  srgb <212*skyf,221*skyf,239*(1+skyf)*0.5>/255]
                        [0.1029  srgb <219*skyf,229*skyf,244*(1+skyf)*0.5>/255]
                        [0.1512  srgb <233*skyf,241*skyf,250*(1+skyf)*0.5>/255]
                        [0.1949  srgb <223*skyf,239*skyf,252*(1+skyf)*0.5>/255]
                        [0.2444  srgb <201*skyf,227*skyf,252*(1+skyf)*0.5>/255]
                        [0.2921  srgb <180*skyf,213*skyf,250*(1+skyf)*0.5>/255]
                        [0.3732  srgb <144*skyf,180*skyf,239*(1+skyf)*0.5>/255]
                        [0.4255  srgb <137*skyf,172*skyf,235*(1+skyf)*0.5>/255]
                        [0.7067  srgb < 97*skyf,126*skyf,198*(1+skyf)*0.5>/255]
                        [0.7740  srgb < 92*skyf,119*skyf,190*(1+skyf)*0.5>/255]
                        [0.8275  srgb < 88*skyf,114*skyf,185*(1+skyf)*0.5>/255]
                        [0.8850  srgb < 85*skyf,111*skyf,180*(1+skyf)*0.5>/255]
                        [0.9425  srgb < 82*skyf,107*skyf,175*(1+skyf)*0.5>/255]
                        [1.0000  srgb < 79*skyf,103*skyf,170*(1+skyf)*0.5>/255]
                }
        }
}

Norbert


Post a reply to this message

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.