#include "functions.inc"

#declare mazemap=
pigment
{
  image_map
  {
    png "maze_prime_1001x1001.png"
  }
}

#declare cols=1001;
#declare rows=1001;
#declare startx=720;
#declare starty=525;

#fopen labyrinth "newmaze.inc" write

#write(labyrinth,"#declare NbColumns = ",cols,";\n")
#write(labyrinth,"#declare NbLines = ",rows,";\n")
#write(labyrinth,"#declare DebutX = ",startx,";\n")
#write(labyrinth,"#declare DebutY = ",starty,";\n")
#write(labyrinth,"#declare GrilleLaby = array[NbLines][NbColumns]\n")
#write(labyrinth,"{\n")

#declare a=0; // rows counter
#while (a < rows)
  #declare b=0; // columns counter
  #write(labyrinth,"{")
  #while (b < cols)
    #declare c=eval_pigment(mazemap, <(0.5+b)*(1/cols), 1-(0.5+a)*(1/rows), 0>);
    #if (c.red=1 & c.green=1 & c.blue=1)
      #declare n=1;
    #else
      #if (c.red=0 & c.green=0 & c.blue=0)
        #declare n=0;
      #else
	#if (c.red=1 & c.green=0 & c.blue=0)
	  #declare n=2;
	#end
      #end
    #end
    #write(labyrinth,n)
    #if (b<cols-1) // all columns except last one
      #write(labyrinth,",")
    #end
    #declare b=b+1;
  #end
  #write(labyrinth,"}")
  #if (a<rows-1) // all rows except last one
    #write(labyrinth,",")
  #end
  #write(labyrinth,"\n")
  #declare a=a+1;
#end
#write(labyrinth,"}")