// Persistence of Vision Ray Tracer Scene Description File
// File: cloudtest2.pov
// Vers: Megapov 1.21
// Desc: Sunset media clouds
// Date: 04/20/06
// Auth: Abe Madey
//

//+w320 +h160 +a0.3 +am2 +bm2
//+w640 +h320 +a0.3 +am2 +bm2
//+w1600 +h800 +a0.3 +am2 +bm2
//+w3200 +h1600 +a0.3 +am2 +bm2

//=================================================================================
// VERSION AND GAMMA SWITCHES
//=================================================================================
#version 3.7;
#declare MPov       = off;

#if (MPov)
  #version unofficial megapov 1.21;
  #include "tone_mapping.inc"	     //include file for Clip_Colors()
  #declare Gamma = 1.0;
#else
  #declare Gamma = 2.2;
#end

//=================================================================================
// DEFAULTS AND INCLUDES
//=================================================================================
#default {pigment {rgb <1,0,0>}}
#default {finish {ambient 0}}
//#default {image_map {gamma srgb}}

#include "colors.inc"
#include "rand.inc"
#include "functions.inc"
#include "transforms.inc"
//#include "TexturesExtra.inc"

//=================================================================================
// SCENE SWITCHES
//=================================================================================
#declare PoF            = off;	// on/off switch for the Position Finder
#declare SeeScreen      = off;	// Gilles Tran's Visibility Test
#declare Rad            = on;		// Radiosity switch

//=================================================================================
// GLOBAL SETTINGS
//=================================================================================
global_settings {
  #if (MPov)
    Clip_Colors()			  // MegaPOV: tone mapping for antialiasing like in version 3.5 (smoother transitions)
    exposure 1
    exposure_gain 1.6
    //max_intersections 1000	//I-stack overflows (default 64) appears in message window (does not work with v.3.7!)
  #end
  #if (version < 3.7)
    hf_gray_16 off
    max_intersections 64
  #end
  assumed_gamma 1.0
  max_trace_level 5			//default [5]
  #if (Rad)
  radiosity {
    pretrace_start 0.08           // start pretrace at this size
    pretrace_end   0.004          // end pretrace at this size
    count 35                      // higher -> higher quality (1..1600) [35]
    nearest_count 5, 1           // higher -> higher quality (1..20) [5]; (new in 3.7) optional 2nd parameter sets adaptive radiosity pretrace
    error_bound 1                 // higher -> smoother, less accurate [1.8]
    recursion_limit 1             // how much interreflections are calculated (1..5+) [3]
    low_error_factor .3           // reduce error_bound during last pretrace step
    gray_threshold 0.0            // increase for weakening colors (0..1) [0]
    minimum_reuse 0.015           // reuse of old radiosity samples [0.015]
    maximum_reuse 0.1							// new parameter 3.7 [0.2]
    brightness 1                  // brightness of radiosity effects (0..1) [1]

    adc_bailout 0.01/2
    normal off                    // take surface normals into account [off]
    media off                     // take media into account [off]
    //save_file "C:\VirtualReality\Data files\POV-Ray files\Script files\Desert\Desert_rad.txt"       // save radiosity data
    //load_file "C:\VirtualReality\Data files\POV-Ray files\Script files\Desert\Desert_rad.txt"       // load saved radiosity data
    always_sample off             // turn sampling in final trace off [on]
    //max_sample 1.0              // maximum brightness of samples
  }
  #end
  //noise_generator 2
}

//=================================================================================
#declare SceneCam =
/*  camera {	// spherical lens for sphere field of view (mappable to a sphere)
    spherical
    location <0,0,0>      // position
    look_at  <0,0,1>      // view
    angle 360             // horizontal degrees
          180             // vertical degrees
  }*/
camera {
  location  <0.0, 0.01, 0>
  direction z
  right     x*image_width/image_height
  look_at   <0.0, 10e4, 10e5>
  //rotate <-15, -30, 0>  
  angle 50
} 

camera{SceneCam }

//=================================================================================
#declare SceneSky=
sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.2824,0.6588,0.984>]
    }
  }
}                 


sky_sphere{SceneSky}
 
//=================================================================================
#declare Sun_alt = 2;
#declare Sun_azm = 5;

#declare Sun=
light_source {
  z*10e6
  color rgb <1, 1, 1>*1
  rotate <-Sun_alt, Sun_azm,0>
  //rotate -x*20
}


light_source{Sun}

//=================================================================================
#declare ground=
sphere{
 -y*(10e5), 10e5   
 pigment{rgb <0.4000,0.3412,0.1961>}
} 
object{ground}

//=================================================================================
#macro MediaSampleParams() method 3 intervals 1 samples 12 jitter .5 #end

#declare atm_shell =
sphere {
  //0, 100
  //scale <1, 0.039999, 1>
  -y*(10e5), 10e5 + 3.00
  hollow
  pigment {rgbt 1}
  interior {
    media {
      scattering {1 rgb 0.01*<1, 0.8, 0.6> extinction 1}
      //absorption rgb 0.2 
      //emission rgb 0.025
      MediaSampleParams()
    }
    media{
      scattering {3 rgb 0.00001 extinction 1}
      absorption rgb 0.05*<0.01, 0.40, 0.95> 
      emission rgb 0.01*<0.9529, 0.9412, 0.6863>
      MediaSampleParams()
    }
  }
}

object {atm_shell}

#declare cloud_shell =
difference {
  sphere {-y*(10e5), 10e5 + 2.17}
  sphere {-y*(10e5), 10e5 + 2.00} 
  hollow
  pigment {rgbt 1} 
  interior {
    media {
      scattering {1, rgb 2*<1, 0.85, 0.9> extinction 1}
      absorption rgb 2  
      emission rgb 0.5*<0.3063, 0.3333, 0.45>
      MediaSampleParams()
      density {
        granite  
        scale 50
        scale 1/10 warp {turbulence 2 lambda 3 octaves 8} scale 10  
        scale 2   
        translate <-1, 0, -1>
        color_map {[0.39 rgb 0][0.46 rgb 1]}
      }
    }
  }
}

object {cloud_shell}