// Persistence of Vision Ray Tracer Scene Description File
// File: BrickWall.pov
// Vers: 3.1
// Desc: A brick wall with different brick sizes
// Date: 2001
// Auth: Ib Rasmussen


#include "colors.inc"
#include "skies.inc"

#version 3.1;
global_settings { assumed_gamma 2.2 }

/************************* Declarations ******************************/

/*--------------------- Camera and Lights ---------------------------*/

#declare CamX = 0;
#declare CamY = 140;
#declare CamZ = -700;

#declare TestCam=camera {
   location  <CamX, CamY, CamZ>
   angle 40
   look_at   < 0, 140,  0 >
}

#declare MainLight=light_source { <0, 0, 0>, colour White*1.5}
#declare CamLight=light_source { <0, 0, 0>, colour White*0.5 }

/*-------------------------- Constants ------------------------------*/

// Brick and mortar dimensions
#declare BHeight=  6.9;
#declare BWidth=  24;
#declare BMortar=  1.25;

/*-------------------------- Textures -------------------------------*/

#declare T_Mortar=texture {
   pigment { granite
      turbulence 0.6
      color_map{
  [0.000, 0.154   color rgbf <0.6, 0.6, 0.466, 0.000>
            color rgbf <0.6, 0.6, 0.577, 0.000>]
  [0.154, 0.300   color rgbf <0.6, 0.6, 0.6, 0.000>
            color rgbf <0.6, 0.6, 0.466, 0.000>]
  [0.300, 0.320   color rgbf <0.4, 0.4, 0.5, 0.000>
            color rgbf <0.5, 0.5, 0.6, 0.000>]
  [0.320, 0.615   color rgbf <0.6, 0.6, 0.6, 0.000>
            color rgbf <0.6, 0.6, 0.466, 0.000>]
  [0.615, 0.812   color rgbf <0.6, 0.6, 0.466, 0.000>
               color rgbf <0.6, 0.6, 0.577, 0.000>]
  [0.812, 1.001   color rgbf <0.6, 0.6, 0.6, 0.000>
               color rgbf <0.1, 0.1, 0.1, 0.000>]
      }
   }
   scale 3
}

#declare T_Brickcolor=texture {
   pigment { bozo
      turbulence 1.0
      color_map{
  [0.0, 0.5   color rgbf <0.50, 0.18, 0.09, 0.0>
           color rgbf <0.65, 0.27, 0.18, 0.0>]
  [0.5, 1.001 color rgbf <0.65, 0.27, 0.18, 0.0>
           color rgbf <0.50, 0.18, 0.09, 0.0>]
      }
   }
   scale 30
}

#declare T_Brick1=texture {
   brick texture {T_Mortar}, texture {T_Brickcolor}
   brick_size <BWidth, BHeight, BWidth/2>
   mortar BMortar
}

#declare T_Brick2=texture {
   brick texture {T_Mortar}, texture {T_Brickcolor scale 2}
   brick_size <BWidth/2, BHeight, BWidth>
   mortar BMortar
}

/*------------------------- Objects ----------------------------------*/

#declare Wall=union {
   union{
      #declare pos = 0;
      #while (pos < 40)
         box { <  0, 0, 0>, <400, BHeight, 30> translate <0,
pos*BHeight, 0> }
         #declare pos = pos + 2;
      #end
      texture { T_Brick2 translate <BWidth/4, 0, BWidth/4> }
   }
   union{
      #declare pos = 0;
      #while (pos < 40)
         box { <  0, 0, 0>, <400, BHeight, 30> translate <0,
(pos+1)*BHeight, 0> }
         #declare pos = pos + 4;
      #end
      texture { T_Brick1 translate <BWidth/2, 0, 0> }
   }
   union{
      #declare pos = 0;
      #while (pos < 40)
         box { <  0, 0, 0>, <400, BHeight, 30> translate <0,
(pos+3)*BHeight, 0> }
         #declare pos = pos + 4;
      #end
      texture { T_Brick1 translate <0, 0, 0> }
   }
}

/***************************** Scene *********************************/

/*--------------- Camera, Lights and Background ---------------------*/

camera { TestCam }

object { MainLight translate < 5000, 5000, -8000> }
object { CamLight translate <CamX, CamY, CamZ> }

sky_sphere { S_Cloud1 }
plane { y, 0 texture { pigment { Gray50 } } }

/*------------------------- Objects ----------------------------------*/

object { Wall translate <-200, 0, 0> }

/*-------------------------end-----------------------------------------*/