#version 3.71;     // image_map in density{} needs pull req #82
global_settings {
    assumed_gamma 1
    ambient_light srgb <1,1,1>
}
background { color rgbft <0,0,0,0,0> }
#declare Camera01 = camera {
    orthographic
    location <0,0,-2>
    direction <0,0,1>
    right x*(image_width/image_height)
    up <0,1,0>
}
#declare Dens00 = density {
    image_map { "Playground.jpg" once map_type 0 interpolate 2 }
    warp { turbulence 0.005 octaves 6 omega 1.23 lambda 7 }
}
#declare Dens00_ImgRange = max_extent(Dens00);
#declare Dens00_NrmScale = <min(1,Dens00_ImgRange.x/Dens00_ImgRange.y),
min(1,Dens00_ImgRange.y/Dens00_ImgRange.x),1>;
#declare Dens01 = density {
    image_map { "Playground.jpg" once map_type 0 interpolate 2 }
}
#declare Pclear = pigment { color srgbft <1,1,1,0,1> }
#declare Tclear = texture { pigment { Pclear } }
#declare Blob00 = blob {
    threshold 0.0001
    cylinder { <0,0.44,0>, <1,0.43,0>, 0.26, 1 scale <1.1,1.1,5> }
}
#declare Dens99 = density {
    potential { Blob00 } poly_wave 1.0
    density_map {
      [ 0 Dens00 ]
      [ 1 Dens01 ]
    }
}
#declare Media01 = media {
    method       3
    samples      30
    jitter       0
    aa_level     4
    aa_threshold 0.1
    emission     rgbft <1,1,1,0,0>
    density { Dens99 }
}
#declare Interior01 = interior { ior 1 media { Media01 } }
#declare Box00 = box { <0,0,0>,<1,1,1> }
#declare ObjDen = object {
    Box00
    texture { Tclear }
    interior { Interior01 }
    translate -0.5
    scale Dens00_NrmScale
    hollow
    scale 1.05
}

//---
camera { Camera01 }
object { ObjDen }