I have my camera inside a hollow sphere with no_image looking at another
sphere.  The problem is, I can see the other sphere but it's reflection
block isn't working.
Is this a bug or am I doing something wrong here?

-tgq

code:
global_settings{
  assumed_gamma 1.0
  ambient_light 1.0
  max_trace_level 25
}

camera {
  direction z
  up y
  right x*image_width/image_height
  location 20*z
  look_at  0
}

light_source{15 15
  looks_like{
    sphere{0 10}
    pigment{rgb 1}
    finish{ambient 15}
  }
}

#declare MD1=
material{
  texture{
    pigment{rgb<0.6, 0.5, 0.2>}
    finish{
      ambient 0
      diffuse 0.05
      brilliance 1.0
      conserve_energy
      reflection {
        0 1
        fresnel on
        metallic 0
      }
    }
  }
  interior{ior 15}
}

sphere{0 5 material{MD1}}
sphere{20*z 1 material{MD1} no_image hollow}
plane{y,-7 pigment{checker rgb 0 rgb 1 scale 4}finish{diffuse.1}}//   TGQ




--
camera{location z*13look_at 0}light_source{15 15looks_like{sphere{0 10
}pigment{rgb 1}finish{ambient 15}}}union{torus{3,0.5rotate x*90}cone{y
*4,.5,-y*8,0}cone{-x*4,.5,x*8,0}pigment{rgb<.7,.6,.4>}finish{ambient 0
diffuse 0reflection{1fresnel on metallic 1}}interior{ior 25}rotate 15}
plane{y,-7pigment{checker rgb 0rgb 1scale 4}finish{diffuse.1}}//   TGQ

Post a reply to this message

Something wrong I guess.  Use no_reflection when dealing with reflective
surfaces.

Bob H.

"Trevor Quayle" <Tin### [at] hotmailcom> wrote in message
news:3ba3d835@news.povray.org...
> I have my camera inside a hollow sphere with no_image looking at another
> sphere.  The problem is, I can see the other sphere but it's reflection
> block isn't working.
> Is this a bug or am I doing something wrong here?

Post a reply to this message

"Trevor Quayle" <Tin### [at] hotmailcom> wrote:

> I have my camera inside a hollow sphere with no_image looking at another
> sphere.  The problem is, I can see the other sphere but it's reflection
> block isn't working.
> Is this a bug or am I doing something wrong here?
> 
> 
Well, the culprit here seems to be fresnel; with fresnel on, only the
minimum reflection value is used on the sphere.

-- 
Margus Ramst

Personal e-mail: mar### [at] peakeduee
TAG (Team Assistance Group) e-mail: mar### [at] tagpovrayorg
Home page http://www.hot.ee/margusrt

Post a reply to this message