#version 3.8; // or 3.7
global_settings{assumed_gamma 1.0}
#default{finish{ambient 1 emission 0 diffuse 0}}

#declare CREATE_INITIAL_IMAGE = on; // render as typical 24-bit .png. Use NO antialiasing (important). 
// This will be the material_map's 'image'. RE-NAME this rendered image as "MMT".
// Then turn this OFF to make the 'final' render.

background{rgb .15}

//----------

#if(CREATE_INITIAL_IMAGE)

camera {
  orthographic
  location  <0, 0, -4.5>
  look_at   <0, 0,  0>
  right     x*image_width/image_height
  angle 67
}
  
  plane {
    -z, 0
    pigment {rgb <0/255, 0, 0.5>}
  }
  
  box {
    <-2.3, -1.8, -0.2>, <2.3, 1.8, -0.2>
    pigment { rgb <1/255, 0, 1> } 
  }
  box {
    <-1.95, -1.3, -0.4>, <1.95, 1.3, -0.3>
    pigment { rgb <2/255, .5, .5> }
  }
  text {
    ttf "crystal.ttf", "The vision", 0.1, 0
    scale <0.7, 1, 1>
    translate <-1.8, 0.25, -0.5>
    pigment { rgb <3/255, 1, 1> } 
  }
  text {
    ttf "crystal.ttf", "Persists!", 0.1, 0
    scale <0.7, 1, 1>
    translate <-1.5, -1, -0.5>
    pigment { rgb <4/255, 1, 1> }
  }
   
#else // to render the FINAL material_map result:

camera {
  perspective
  location  <3, 2.5, -4>
  look_at   <.6, .5,  0>
  right     x*image_width/image_height
  angle 25 // 25
}


box{.0001,.9999
	
// the material_map...
texture{
material_map{
png "MMT.png" once // DO NOT USE INTERPOLATE 2
		
texture{pigment{rgb <1,0,0>}} // RED-- for 0/255 red
texture{pigment{rgb <0,1,0>}} // GREEN-- for 1/255 red
texture{pigment{rgb <0,0,1>}} // BLUE-- for 2/255 red
texture{pigment{rgb 0}} // BLACK-- for 3/255 red
texture{pigment{rgb 1}} // WHITE-- for 4/255 red
		      }
	}		
}

#end