/*
   povray_370 optics.pov +p +w320 +h240
   povray optics.pov +p +w320 +h240
   povray_370 optics_mod.pov +p +w640 +h480
   povray optics_mod.pov +p +w640 +h480
*/

#version 3.7;
global_settings { assumed_gamma 1.0 } 

#include "colors.inc"

#default {finish {ambient 0}}

global_settings {
    assumed_gamma 1
    max_trace_level 5
photons {
        count 150000
        max_trace_level 9
        media 100, 2
   }
}

#declare CamPos = < 0, 18, 0>;

camera {
    location CamPos
    right x*image_width/image_height // keep propotions with any aspect ratio
    look_at < 0, 0, 0>
    angle 35
}

light_source {<-150, 0.5, 0>, color rgb < 1.2, 1, 1.5>
    spotlight radius 0.3 falloff 0.35 point_at < 0, 0.5, 0>
    photons {refraction on reflection on}
}

box {<-7,-0.1,-3>, < 6, 1, 4> hollow
    texture {pigment {color rgbf 1}}
interior {
        media {
            scattering {1, color White extinction 0}
            method 3
            intervals 1 samples 4
        }
    }
    photons {target}
}

#declare MirrorTex1 =
texture {
    pigment {color White}
    finish {ambient 0 diffuse 0 reflection 1}
}

#declare BlueMirrorTex =
texture {
    pigment {color rgb < 1, 1, 0> filter 1}
    finish {ambient 0 diffuse 0 reflection Blue}
}

#macro Mirror(Pos, Ang, Width, Height, Tex)
	box {<-0.1,-0.1,-Width/2>, < 0, Height, Width/2>
	    texture {Tex}
	    rotate -y*Ang
	    translate Pos
	}
#end

object {Mirror(<-3, 0, 0>, 3*45, 2, 1, BlueMirrorTex)}
object {Mirror(<-3, 0, 3>,-45, 2, 1, MirrorTex1)}