// bounding for catmul-rom spline
// by its calculated Bezier control points 

global_settings {
  assumed_gamma 1
}

camera {location <0,0.5,-1>*0.8 look_at 0}
#default {finish {ambient .5 diffuse 0.6}}
background{rgb 1}


light_source{
	<-4.470,4.533,4.883>
	rgb 1
}

light_source{
	<4.470,4.533,-4.883>
	rgb 1
}



#declare N = 5;	// Number of spline segments

#declare crPoint = array[N+3] // Spline starts from crPoint[1] and ends at crPoint[N+1]
															//  crPoint[0] and crPoint[N+2] are not on curve
#declare R = array[N+3]
#declare crPoly=array[N][4];  // Polynomial coefficients for every N segment
#declare bPoly=array[N][4];		// Bezier control points for corresponding segments
#declare Bound=array[N][2];		// Bound boxes 

#declare s = seed(1117);

#local  i = 0;
#while (i<N+3)
   #declare crPoint[i] = <rand(s)*i/10,rand(s)*i/10,rand(s)*i/10>;
   #declare R[i] = (i/2+rand(s))/100;
   #local i=i+1;
#end


#declare Sweep=sphere_sweep {
	cubic_spline N+3

	#local i = 0;
	#while (i<N+3)
		crPoint[i] R[i]
	  #local i=i+1;
	#end                 
	pigment {color rgb <0.0253 0.0478	0.078>}
}



// Calculate Catmull-Rom segment coefficients:

#local i=1;
#while(i<N+1)  
  #declare crPoly[i-1][0]=crPoint[i];
  #declare crPoly[i-1][1]=-0.5*crPoint[i-1]+0.5*crPoint[i+1];
  #declare crPoly[i-1][2]=crPoint[i-1]-2.5*crPoint[i]+2*crPoint[i+1]-0.5*crPoint[i+2];
  #declare crPoly[i-1][3]=-0.5*crPoint[i-1]+1.5*crPoint[i]-1.5*crPoint[i+1]+0.5*crPoint[i+2];
  #local i=i+1;
#end
               

// Calculate Bezier segment coefficients:

#local i=0;
#while(i<N)  
  #declare bPoly[i][0]=crPoint[i+1];
  #declare bPoly[i][1]=crPoly[i][0]+crPoly[i][1]/3;
  #declare bPoly[i][2]=crPoly[i][0]+(2*crPoly[i][1]+crPoly[i][2])/3;
  #declare bPoly[i][3]=crPoint[i+2];
  #local i=i+1;
#end
               

// Calculate Bounding Boxes

#local i=0;
#while(i<N)
  #local xMin=bPoly[i][0].x;
  #local yMin=bPoly[i][0].y;
  #local zMin=bPoly[i][0].z;

  #local xMax=xMin;
  #local yMax=yMin;
  #local zMax=zMin;
	#local j=0;
	#while(j<4)     
	  
	  #if(bPoly[i][j].x<xMin) 
	    #local xMin=bPoly[i][j].x;
	  #end

	  #if(bPoly[i][j].y<yMin) 
	    #local yMin=bPoly[i][j].y;
	  #end

	  #if(bPoly[i][j].z<zMin) 
	    #local zMin=bPoly[i][j].z;
	  #end
	    
	  #if(bPoly[i][j].x>xMax) 
	    #local xMax=bPoly[i][j].x;
	  #end

	  #if(bPoly[i][j].y>yMax) 
	    #local yMax=bPoly[i][j].y;
	  #end

	  #if(bPoly[i][j].z>zMax) 
	    #local zMax=bPoly[i][j].z;
	  #end
	    
    #local j=j+1;
  #end                                                                
  #local rShift=max(R[i],R[i+1],R[i+2])*1.001;;
  #declare Bound[i][0]=<xMin,yMin,zMin>-rShift;
  #declare Bound[i][1]=<xMax,yMax,zMax>+rShift;
  #local i=i+1;
#end

                                    


#declare BoundObject=union{

	#local i=0;
	#while(i<N)  
	  box{Bound[i][0],Bound[i][1] hollow
	    pigment{rgbt <rand(s),rand(s),rand(s),0.5>}
	  }
	  #local i=i+1;
	#end
	
}
                                    
                                    
#declare Object = union{
  object{Sweep}
  object{BoundObject}
}  


#if(1)                            
#declare Object=#object{Object                                      
  #local vv=-(max_extent(Object)-min_extent(Object))/2;
  translate vv-min_extent(Object)
  scale 0.5/vlength(vv) 
  //rotate -x*90
  rotate y*-45
//  rotate z*-90
  
}  
#end            



               
#object{Object}