/* This scene produces image that, with gamma 2.2, matches the synthetic image of the
   Cornell box available at http://www.graphics.cornell.edu/online/box/box.jpg.
   The scene and colors are not 100% accurate and can be used for
   qualitative/artistic purposes only.
  
   June 01 2000 kari@kivisalo.net

*/

/*
  Modified by Mike Andrews October 2001
*/


#version unofficial megapov 0.7;

#declare Diffuse=1.2; // With this value brihtness=1
#declare RadQuality=3; // 1=good enough

global_settings{
  assumed_gamma 1.0
  ini_option "+qr"
  radiosity{
    pretrace_start 16/image_width
    pretrace_end max(2, 16/pow(2, RadQuality))/image_width
    count 100*RadQuality
    recursion_limit 2+RadQuality 
    adc_bailout 0.001
    nearest_count 4*RadQuality
    error_bound 1/RadQuality
    low_error_factor 0.1
    brightness 1.2/Diffuse
    gray_threshold 0.5     
  }
} 

#declare Finish=finish{diffuse Diffuse brilliance 0.6 ambient 0}

//*
#declare sX = 0.45;
#declare sZ = 0.4;
#declare N = 1+RadQuality;
#declare cL = 0.995*y; 

box { -<sX,0.015,sZ>/2, <sX,0.015,sZ>/2
  pigment { rgb 1 }
  finish { ambient 1 diffuse 0 }
  translate cL
  no_shadow
}

#declare C1 = 0; #while (C1 < N)
  #declare C2 = 0; #while (C2 < N)
    light_source {
      0, rgb 4.5/Diffuse
      area_light x*sX/N, z*sZ/N, 4, 4 jitter
      spotlight
//      radius 1 falloff 90 tightness -0.6
      radius -90 falloff 90 tightness 1
      point_at -y
      fade_power 2
      fade_distance sqrt(sX*sZ)/N
      translate <sX*((C1+0.5)/N-0.5), 0, sZ*((C2+0.5)/N-0.5)> + cL
    }
  #declare C2 = C2 + 1; #end
#declare C1 = C1 + 1; #end
// */

/* 
light_source{
  0.995*y color 4.5/Diffuse
  spotlight radius 1 falloff 90 tightness -0.6 point_at 0
  area_light <0.45, 0, 0>,<0, 0, 0.4>,20,20 adaptive 0
  fade_power 2
  fade_distance 0.45
}
// */

#declare BaseTex=texture{pigment{rgb<0.891,0.6,0.21>}finish{Finish}}
#declare RedTex=texture{pigment{rgb<0.442,0,0>}finish{Finish}}
#declare GreenTex=texture{pigment{rgb<0.02,0.15,0.002>}finish{Finish}}

camera{
  location<0,0,-3.82>
  right x
  direction 1.365*z
  look_at <0,0,0>
}

#declare Box=box{-1,1 scale <1,0.001,1> translate -y}

object{Box texture{BaseTex}}
object{Box rotate 90*z texture{GreenTex}}
object{Box rotate 180*z texture{BaseTex}}
object{Box rotate 270*z texture{RedTex}}
object{Box rotate -90*x texture{BaseTex}}

box{
  -0.5,0.5 translate 0.5*y scale 0.61
  rotate 17*y translate<0.32,-1,-0.38> texture{BaseTex}
}

box{
  -0.5,0.5 translate 0.5*y scale <1,2,1>*0.61
  rotate -17*y translate<-0.35,-1,0.27> texture{BaseTex}
}

/*
box{
  -0.5,0.5 scale<0.45,0.015,0.4> translate 0.995*y
  pigment{rgb<1,1,1>} finish{ambient 1 diffuse 0} 
  no_shadow
}
// */