#version 3.6

sphere { <0,0,0> , 10*sqrt(3)
	pigment { granite scale 48.21 }
	finish { reflection 0.2 phong 0.376 }
	normal { granite 0.1/10  }
	hollow
}


sphere { <+10,0,0>*sqrt(3),3
	pigment { color <0,1,0> }
	finish { phong 0.5 metallic reflection 0.333 }
}

sphere { <-10,0,0>*sqrt(3),3
	pigment { color <0,0,1> }
	finish { phong 0.5 metallic reflection 0.333 }
}

cylinder { <-10,0,0>*sqrt(3), <+10,0,0>*sqrt(3), 0.5
	pigment { color <1,1,0> }
	finish { phong 0.5 metallic reflection 0.333 }
}


#declare S=seed(4711);
#declare I=0;
#while(I<444)

	#declare M = <10,0,0>*sqrt(3);
	#declare M = vrotate(M,y*360*rand(S));
	#declare M = vrotate(M,z*360*rand(S));
	#declare M = vrotate(M,x*360*rand(S));
	#declare R = 0.8 + rand(S)*0.195;

	sphere { M*R, 0.5 + rand(S)*0.75
		pigment { color rgb<1,0.1,0.2> }
		finish { phong 0.5 reflection 0.2}
	}
	
	cylinder { M*R, M*1.1, 0.375
		pigment { color rgb<0.7,0.5,0.3> }
		finish { phong 0.5 }
	}
	
	#declare I=I+1;
#end

#declare SPL = spline {
	cubic_spline
//	linear_spline
	
	#declare W=1;
	#while(W<=360)
	
		W/360, 9*<sin(W*3.141592/180), cos(0.7+W*3.141592/180)/4-0.15 , cos(0.1+W*3.141592/90)>
	
	#declare W=W+1;
	#end
	
}

light_source { <-10,3,0> color <0.8,0.5,0.5>
	area_light <1,0,0>, <0,1,0>, 4,4 jitter  orient circular
}
light_source { <+10,3,0> color <0.5,0.6,0.8>
	area_light <1,0,0>, <0,1,0>, 4,4 jitter orient circular
}

#declare vclock = clock+0.372;
#while(vclock>1)
	#declare vclock = vclock-1.0;
#end

camera {
//	location <-9,-9,-9>
//	look_at <0,0,0>

	location SPL(clock)
	look_at SPL(vclock)
	
	angle 60
}