Wasn't it Stephen McAvoy who wrote:
>On Thu, 18 Dec 2003 18:11:33 +0000, Mike Williams <nos### [at] econymdemoncouk>
>wrote:
>
>>
>>http://www.econym.demon.co.uk/plugins/hf.htm
>
>Nothing to do with this thread, just wanted to say I love the backgrounds on you
>site. If you weren't "churchy" I would say, "Can I have some of what you've been
>smoking" :-}
>

It's just a few randomized f_noise3d pigment functions.


camera {orthographic  right 2*x up 2*y 
        direction z  location <0, 0, -100>}

#include "functions.inc"
#declare R1=seed(51);

#declare A=rand(R1);
#declare B=rand(R1);

#declare F=function{f_noise3d(x*10*A,y*10*A,0)}
#declare G=function{f_noise3d(x*10*B,y*10*B,0)}

plane {z,0 pigment {
    function {
        F(abs(x),abs(y),0)
    }
      color_map {
        #local C = 0;
        #while (C < 1.1)
          #declare C1=<rand(R1), rand(R1), rand(R1)>;
          [C rgb C1]
          #declare C = C + .01 + rand(R1)*.1;
          [C rgb C1]
        #end }
  }
  finish {ambient 1}
}

plane {z,-1 pigment {
    function {
        G(abs(x),abs(y),0)
    }
      color_map {
        #local C = 0;
        #while (C < 1.1)
          #declare C1=<rand(R1), rand(R1), rand(R1), rand(R1)>;
          [C rgbt C1]
          #declare C = C + .01 + rand(R1)*.1;
          [C rgbt C1]
        #end }
  }
  finish {ambient 1}
}

-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message