"Paolo Gibellini" <p.g### [at] teinoscom> wrote in message 
news:44058e5e$1@news.povray.org...
>I love the clouds a lot, is a problem share the texture?

And I will love to share that, Paolo. Not much to it at all. In fact, it's 
probably way too simple for a good rendering. Is a WIP, of course.

I tried to get better cloud colors by using a gradient pattern on a plane 
between them and the sunlight so it would look like it gets brighter toward 
the horizon. I rendered this part alone before giving it to you and I added 
the "air" because it wasn't dark enough without that. The camera needed to 
be in this, too, or else it might be trouble to get looking right again.

/* BEGIN */
camera {
 location <18,-3.85,-24>
 look_at <4.5,3.5,0>
 angle 40
}

/* AIR */

box {
 <-25,-5,-10>,<25,20,10>
 hollow
 pigment {
  color rgbt 1
 }
 interior {
  media {
   samples 15
   intervals 8
   scattering {
    1,0.02
    extinction 0.9
   }
  }
 }
}

light_group {
// sun
light_source {
 150*z, <1.5,1.25,1>/2
 media_interaction on
}
// cloud color projection trick
plane {
 -z,-140
 pigment {
  function {abs(y)}
  color_map {
   [0 color rgbf <1,0.9,0.8,0.9>]
   [0.2 color rgbf <1.1,1.1,0.1,1.1>]
   [0.4 color rgbf <1.25,0.25,0.1,1.1>]
   [0.6 color rgbf <1.5,0.1,0.25,1.1>]
   [1 color rgbf <0.1,0.1,0.1,0.1>]
  }
 }
 no_image no_reflection
}
/* CLOUDS */
box {
 <-150,25,0>,<50,30,300>
 hollow
 pigment {
  color rgbt 1
 }
 interior {
  media {
   //method 1
   samples 50
   //intervals 4
   absorption <0.25,0.33,0.67>
   emission <0.3,0.1,0.125>
   scattering {
    1,0.25
    extinction 0.8
   }
   density {
    granite
    density_map {
     [0.67 rgb 0]
     [0.7 rgb 2]
     [1 rgb 3]
    }
    scale <75,50,50>
   }
  }
 }
} // end clouds
} // end light_group

sky_sphere {
 pigment {
  granite
  color_map {
   [0.1 color rgb <0.5,0.7,0.9>*3]
   [0.125 color rgb <0.3,0.5,0.6>*1.5]
   [0.15 color rgbt 1]
  }
  scale 0.025
 }
 pigment {
  function {abs(y)}
  color_map {
   [0 color rgbt <1.4,1.2,0.3,0>]
   [0.1 color rgbt <2,0.75,0.1,0.05>]
   [0.3 color rgbt <0.1,0.3,0.6,0.1>]
   [0.6 color rgbt <0.1,0.2,0.3,1>]
  }
 }
 pigment {
  gradient z
  color_map {
   [0 color rgbt 0.3]
   [0.25 color rgbt 0.9]
   [1 color rgbt 1]
  }
  scale 2 translate -z
 }
}

/* END */

Post a reply to this message