POV-Ray : Newsgroups : povray.binaries.images : Vovin : Re: Vovin Server Time
28 Mar 2024 21:20:29 EDT (-0400)
  Re: Vovin  
From: Simon J  Cambridge
Date: 17 Nov 2022 05:35:00
Message: <web.63760cc0b34679c67b307bafc9cc1e6f@news.povray.org>
Thomas de Groot <tho### [at] degrootorg> wrote:
> Op 16-11-2022 om 12:10 schreef Simon J. Cambridge:
> > Hello again. I thought I would share this one, recently created, and see what
> > you think. I have been trying to get make simple yet effective media clouds for
> > some time - in order to speed up the render - and I feel I am a bit closer with
> > this one. It still takes a decent time to render, but less than others I have
> > tried in the past. The Vovin (beasts from my books) are modelled in hamapatch
> > (as I still haven't shifted to blender - so much to do and so little time!)
> >
> > Cheers,
> >
> > Simon J. Cambridge
> >
> > (See my other stuff on my website - www.landofthefirst.com)
>
> As always, very impressive.
>
> For media clouds, have you experimented with those from Abe Madey?
>
>
https://news.povray.org/povray.binaries.scene-files/thread/%3Cweb.4447da16ade663f78069ddd30@news.povray.org%3E/?ttop=
243615&toff=50
>
> They are very good, and, in my experience, not too slow to render
> although that always is the trade off with media.
>
> That landscape smells of mandelbrot fractals... ;=)
>
> --
> Thomas

Hi Thomas,

Thank you, and thank you for the link.

The landscape is f_ridged_mf. One of my favourites. I just love the way it
looks. Adding turbulence spoils it, I feel.

The code for the clouds is similar to that used by Abe Madey. However, I wanted
a cumulus look, but across the entire sky.

Here is the code:

#macro SkyShell(minAlt, maxAlt, sc, Int)
    difference
    {
        plane {<0, 1, 0>, 0 translate <0, 10000000+maxAlt, 0> }
        plane {<0, 1, 0>, 0 rotate <0, 180, 0> translate <0, 10000000+minAlt, 0>
}
        hollow
        texture {pigment {color rgbf 1}}
        interior {Int}
        translate <0, -10000000, 0>
        scale sc
    }
#end

SkyShell(30001, 31001, 1
    interior {
        media {
            scattering {4, color rgb <0.01, 0.01, 0.9>*0.0001 extinction 1}
        }
    }
)

#if (CloudsOK=1)
    SkyShell(20000, 30000, 1
        interior{
            media{
                scattering{1, <1, 0.9, 0.8>*0.0001}
                samples 100
                density
                {
                    wrinkles
                    scale <20000, 10000, 20000>
                    turbulence 0.3
                    color_map {
                        [0.62 color rgb 0]
                        [0.64 color rgb 0.035]
                        [0.66 color rgb 0.850]
                        [0.68 color rgb 1]
                    }
                }
                density
                {
                    crackle
                    form<1, 0, 0>
                    scale 2000
                    //turbulence 0.5
                    color_map {
                        [0.0 color rgb 1]
                        [1.0 color rgb 0]
                    }
                }
                density
                {
                    gradient y
                    scale 10000
                    color_map {
                        [0.1 color rgb 0]
                        [0.4 color rgb 1]
                        [0.8 color rgb 1]
                        [0.9 color rgb 0]
                    }
                }
            }
        }
    )
#end


As you can see, I am using a high sample count. I might try Mr Madey's approach
and see what happens.

Cheers,

Simon J. Cambridge.


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.